blob: 75c27222a81ecf8a491178f404f3badf03b8140d (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
|
# Maintainer: Caleb Maclennan <caleb@alerque.com>
# Maintainer: Adrián Pérez de Castro <aperez@igalia.com>
pkgname=sile
pkgdesc='Modern typesetting system inspired by TeX'
pkgver=0.10.5
pkgrel=2
arch=('x86_64')
url='https://www.sile-typesetter.org'
license=('MIT')
_lua_deps=('cassowary'
'cosmo'
'cliargs'
'expat'
'filesystem'
'linenoise'
'lpeg'
'luaepnf'
'penlight'
'repl'
'sec'
'socket'
'stdlib'
'vstruct'
'zlib')
depends=('fontconfig'
'freetype2'
'harfbuzz'
'gentium-plus-font'
'icu'
'libpng' # this goes with libtexpdf if ever split out to a library package
'lua'
"${_lua_deps[@]/#/lua-}"
'zlib')
# Note find via find-deps; needs rebuilding any time versions of these change;
# currently missing several because parent packages are missing the provides=()
depends+=('libfreetype.so'
'libharfbuzz.so'
'libicudata.so'
'libicui18n.so'
'libicuio.so'
'libicuuc.so')
checkdepends=('poppler')
provides=('libtexpdf.so')
source=("https://github.com/sile-typesetter/sile/releases/download/v$pkgver/$pkgname-$pkgver.tar.bz2")
sha256sums=('a14fe23af242ba723aed699048b10abf60d1809390ac543140b80e057c4b4b9b')
build () {
cd "$pkgname-$pkgver"
./configure \
--prefix /usr \
--with-system-luarocks
make all
}
check () {
cd "$pkgname-$pkgver"
make check
}
package () {
cd "$pkgname-$pkgver"
make install DESTDIR="$pkgdir"
install -Dm644 -t "$pkgdir/usr/share/doc/$pkgname" README.md documentation/sile.pdf
cp -ar examples "$pkgdir/usr/share/doc/$pkgname"
install -Dm644 -t "$pkgdir/usr/share/licenses/$pkgname" LICENSE
}
|