blob: 34c89e9f56243e0fa83a2bc1684e7b8b8be32b4e (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
|
# Maintainer: Caleb Maclennan <caleb@alerque.com>
# Maintainer: Adrián Pérez de Castro <aperez@igalia.com>
pkgname=sile-git
pkgdesc='Modern typesetting system inspired by TeX'
pkgver=0.10.4
pkgrel=1
arch=('x86_64')
url='https://www.sile-typesetter.org'
license=('MIT')
_lua_deps=('cassowary'
'cosmo'
'cliargs'
'expat'
'filesystem'
'linenoise'
'lpeg'
'luaepnf'
'penlight'
'repl'
'sec'
'socket'
'stdlib'
'vstruct'
'zlib')
depends=('fontconfig'
'harfbuzz'
'gentium-plus-font'
'icu'
'libpng' # this goes with libtexpdf if ever split out to a library package
'lua'
"${_lua_deps[@]/#/lua-}")
makedepends=('git'
'noto-fonts-cjk'
'poppler'
'ttf-gentium-basic'
'ttf-sil-scheherazade')
checkdepends=('lua-busted')
provides=('libtexpdf.so' "${pkgname%-git}")
conflicts=("${pkgname%-git}")
source=("git://github.com/sile-typesetter/${pkgname%-git}.git"
"git://github.com/sile-typesetter/libtexpdf.git")
sha256sums=('SKIP' 'SKIP')
pkgver() {
cd "${pkgname%-git}"
git describe --tags --abbrev=7 --match="v*" HEAD | sed 's/^v//;s/\([^-]*-g\)/r\1/;s/-/./g'
}
prepare () {
cd "${pkgname%-git}"
git submodule init
git config submodule.libtexpdf.url "$srcdir/libtexpdf"
git submodule update
./bootstrap.sh
}
build () {
cd "${pkgname%-git}"
./configure --prefix=/usr --with-system-luarocks
make all
make docs
make examples
}
check () {
cd "${pkgname%-git}"
make busted
}
package () {
cd "${pkgname%-git}"
make install DESTDIR="$pkgdir"
install -Dm644 -t "$pkgdir/usr/share/doc/${pkgname%-git}" README.md documentation/sile.pdf
cp -ar examples "$pkgdir/usr/share/doc/${pkgname%-git}"
install -Dm644 -t "$pkgdir/usr/share/licenses/${pkgname%-git}" LICENSE
}
|