blob: 58a3ef4044ba0fa7e099c4142981f5c0865e5206 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
|
# Maintainer: Caleb Maclennan <caleb@alerque.com>
# Maintainer: Adrián Pérez de Castro <aperez@igalia.com>
_pkgname=sile
pkgname=$_pkgname-luajit
pkgdesc='The SILE Typesetter, a modern typesetting system inspired by LaTeX, customizable in Lua'
pkgver=0.14.2
pkgrel=1
arch=(x86_64)
url=https://www.sile-typesetter.org
_url="https://github.com/sile-typesetter/$_pkgname"
license=(MIT)
_luadeps=(bit32
cassowary
cldr
cliargs
compat53 # Not needed for Lua 5.3+, LuaJIT is 5.1(ish)
cosmo
expat
filesystem
fluent
linenoise
loadkit
lpeg
luaepnf
luarepl
luautf8
penlight
sec
socket
vstruct
zlib)
depends=(glibc
fontconfig
freetype2
harfbuzz
gentium-plus-font
git
icu
libpng # this goes with libtexpdf if ever split out to a library package
luajit
"${_luadeps[@]/#/lua51-}"
zlib)
depends+=(libfreetype.so
libharfbuzz.so
libicudata.so
libicui18n.so
libicuio.so
libicuuc.so)
optdepends=('libertinus-font: math package default font'
'noto-fonts-cjk: tate enabled classes default font')
checkdepends=(poppler)
provides=(libtexpdf.so
"$_pkgname=$pkgver")
conflicts=("$_pkgname")
_archive="$_pkgname-$pkgver"
source=("$_url/releases/download/v$pkgver/$_archive.tar.xz")
sha256sums=('a3de247d9c21a3b26e9bef10865dc04ccf72021285aa1197365519a36f5062e0')
build () {
cd "$_archive"
./configure \
--prefix /usr \
--with-luajit \
--with-system-luarocks
make all
}
check () {
cd "$_archive"
make check
}
package () {
cd "$_archive"
make install DESTDIR="$pkgdir"
mv "$pkgdir/usr/share/licenses/"{$_pkgname,$pkgname}
}
|