blob: f9bf526029de5c2731e67a9b258baa4dca171115 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
|
# Maintainer: Caleb Maclennan <caleb@alerque.com>
_pkgname=sile
pkgname=$_pkgname-luajit
pkgdesc='Modern typesetting system inspired by TeX'
pkgver=0.10.15
pkgrel=3
arch=(x86_64)
url=https://www.sile-typesetter.org
license=(MIT)
_lua_deps=(bit32 # Upstream Issue: https://github.com/sile-typesetter/sile/issues/1189
cassowary
compat53 # Not needed for Lua 5.3+, LuaJIT is 5.1(ish)
cosmo
cliargs
expat
filesystem
linenoise
lpeg
luaepnf
penlight
repl
sec
socket
stdlib
utf8
vstruct
zlib)
depends=(fontconfig
freetype2
harfbuzz
gentium-plus-font
icu
libpng # this goes with libtexpdf if ever split out to a library package
luajit
"${_lua_deps[@]/#/lua51-}"
zlib)
# Note find via find-deps; needs rebuilding any time versions of these change;
# currently missing several because parent packages are missing the provides=()
depends+=(libfreetype.so
libharfbuzz.so
libicudata.so
libicui18n.so
libicuio.so
libicuuc.so)
checkdepends=('poppler')
provides=(libtexpdf.so
"$_pkgname=$pkgver")
conflicts=("$_pkgname")
source=("https://github.com/sile-typesetter/sile/releases/download/v$pkgver/$_pkgname-$pkgver.tar.xz")
sha256sums=('49b55730effd473c64a8955a903e48f61c51dd7bb862e6d5481193218d1e3c5c')
build () {
cd "$_pkgname-$pkgver"
./configure \
--prefix /usr \
--with-luajit \
--with-system-luarocks
make all
}
check () {
cd "$_pkgname-$pkgver"
make check
}
package () {
cd "$_pkgname-$pkgver"
make install DESTDIR="$pkgdir"
}
|