blob: ba785e01c30bf05a9f495dad708f738443b5f397 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
|
# Maintainer: Caleb Maclennan <caleb@alerque.com>
# Maintainer: Adrián Pérez de Castro <aperez@igalia.com>
_pkgname=sile
pkgname=$_pkgname-luajit-git
pkgdesc='Modern typesetting system inspired by TeX'
pkgver=0.10.14.r0.g175595a
pkgrel=1
arch=('x86_64')
url='https://www.sile-typesetter.org'
license=('MIT')
_lua_deps=('cassowary'
'cosmo'
'cliargs'
'expat'
'filesystem'
'linenoise'
'lpeg'
'luaepnf'
'penlight'
'repl'
'sec'
'socket'
'stdlib'
'utf8'
'vstruct'
'zlib')
depends=('fontconfig'
'freetype2'
'harfbuzz'
'gentium-plus-font'
'icu'
'libpng' # this goes with libtexpdf if ever split out to a library package
'luajit'
"${_lua_deps[@]/#/lua51-}"
'zlib')
# Note find via find-deps; needs rebuilding any time versions of these change;
# currently missing several because parent packages are missing the provides=()
depends+=('libfreetype.so'
'libharfbuzz.so'
'libicudata.so'
'libicui18n.so'
'libicuio.so'
'libicuuc.so')
makedepends=('git')
checkdepends=('poppler')
provides=('libtexpdf.so'
"$_pkgname=$pkgver")
conflicts=("$_pkgname")
source=("git://github.com/sile-typesetter/$_pkgname.git"
"git://github.com/sile-typesetter/libtexpdf.git")
sha256sums=('SKIP'
'SKIP')
pkgver() {
cd "$_pkgname"
git describe --long --tags --abbrev=7 --match="v*" HEAD |
sed 's/^v//;s/\([^-]*-g\)/r\1/;s/-/./g'
}
prepare () {
cd "$_pkgname"
git submodule init
git config submodule.libtexpdf.url "$srcdir/libtexpdf"
git submodule update
./bootstrap.sh
}
build () {
cd "$_pkgname"
./configure \
--prefix /usr \
--docdir /usr/share/doc/$pkgname \
--with-luajit \
--with-system-luarocks
make all
}
check () {
cd "$_pkgname"
make check
}
package () {
cd "$_pkgname"
make install DESTDIR="$pkgdir"
mv "$pkgdir/usr/share/licenses/"{sile,$pkgname}
}
|