blob: 671c1c56b95fe720ba9fefaebd4a2491855d29eb (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
|
# Maintainer: tarball <bootctl@gmail.com>
pkgname=silverbullet
pkgver=0.8.4
pkgrel=1
pkgdesc='Clean Markdown-based writing/note taking application'
arch=(any)
url='https://github.com/silverbulletmd/silverbullet'
license=(MIT)
depends=(deno)
source=(
"$pkgname-$pkgver.tar.gz::$url/archive/refs/tags/$pkgver.tar.gz"
"$pkgname.service"
)
sha256sums=('bfbfec013bba9674c3bc065c62b53c063d1a090bf1e857df4fa56e9c58cf389f'
'b32f789c76e6db00e69bfbb7b00567dbb84104a723b3130e1afe55b7a72bbb59')
build() {
cd "$pkgname-$pkgver"
deno task build
deno task bundle
}
check() {
cd "$pkgname-$pkgver"
deno task test
}
package() {
install -dm755 "$pkgdir/etc/default"
cat >"$pkgdir/etc/default/$pkgname" <<EOF
HOST=localhost
PORT=3000
EOF
install -Dm644 "$pkgname.service" \
"$pkgdir/usr/lib/systemd/system/$pkgname.service"
cd "$pkgname-$pkgver"
install -Dm644 "dist/$pkgname.js" \
"$pkgdir/usr/lib/$pkgname/$pkgname.js"
install -Dm644 LICENSE.md \
"$pkgdir/usr/share/licenses/$pkgname/LICENSE"
}
|