PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43

pkgbase='simple-thumbnailers'
pkgname=(simple-thumbnailer-{pdf,vid,xcf})
pkgver=r6.2ee7d7e
pkgrel=1

arch=('any')
url='https://gitlab.com/zoli111/simple-thumbnailers'
license=('GPL')
source=('git+https://gitlab.com/zoli111/simple-thumbnailers')
sha256sums=('SKIP')
makedepends=('git')

pkgver() {
	cd "simple-thumbnailers" || exit
	printf "r%s.%s" "$(git rev-list --count HEAD)" "$(git rev-parse --short=7 HEAD)"
}

_package() {
	cd "simple-thumbnailers/$1/" || exit
	install -d "$pkgdir/usr/bin/" "$pkgdir/usr/share/thumbnailers/"
	install "simple-thumbnailer-$1" "$pkgdir/usr/bin/"
	install "simple-thumbnailer-$1.thumbnailer" "$pkgdir/usr/share/thumbnailers/"
}

package_simple-thumbnailer-pdf() {
	depends=('poppler')
	conflicts=('evince') # evince already provides PDF thumbnailing support
	pkgdesc='Minimal PDF thumbnailer'
	_package pdf
}

package_simple-thumbnailer-vid() {
	depends=('ffmpeg')
	conflicts=('totem' 'ffmpegthumbnailer')
	pkgdesc='Minimal video thumbnailer'
	_package vid
}

package_simple-thumbnailer-xcf() {
	depends=('gimp')
	pkgdesc='Minimal XCF thumbnailer'
	_package xcf
}