blob: f66e3c4ba51640d46056532468066a7326df89e4 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
|
# Maintainer: Klaus Alexander Seistrup <klaus@seistrup.dk>
# -*- sh -*-
pkgname='simplex-chat-bin'
_pkgname="${pkgname%%-bin}"
pkgver=4.3.2
pkgrel=1
pkgdesc='A 100% private-by-design chat platform (pre-compiled)'
arch=('x86_64')
_platform='ubuntu-20_04-x86-64'
url='https://simplex.chat/'
_rawurl='https://raw.githubusercontent.com/simplex-chat/simplex-chat/master'
source=(
"$_pkgname-$pkgver::https://github.com/$_pkgname/$_pkgname/releases/download/v$pkgver/$_pkgname-$_platform"
"$_rawurl/PRIVACY.md"
"$_rawurl/README.md"
"$_rawurl/docs/CLI.md"
"$_rawurl/docs/SIMPLEX.md"
"$_rawurl/docs/SQL.md"
"$_rawurl/scripts/message_views.sql"
)
license=('AGPL3')
depends=(
'gmp'
'openssl-1.1'
'zlib'
)
provides=('simplex-chat')
conflicts=('simplex-chat')
package() {
cd "$srcdir" || exit 1
install -Dm0755 "$_pkgname-$pkgver" "$pkgdir/usr/bin/$_pkgname"
for doc in {PRIVACY,README,CLI,SIMPLEX,SQL}.md; do
install -Dm0644 "$doc" "$pkgdir/usr/share/doc/$_pkgname/$doc"
done
install -Dm0644 message_views.sql "$pkgdir/usr/share/doc/$_pkgname/message_views.sql"
}
sha256sums=(
'027492a5c884b1628e3f91adb5ad3a857f70a692bc5805a647944a9aa33cfd0a'
'SKIP' 'SKIP' 'SKIP' 'SKIP' 'SKIP' 'SKIP'
)
sha512sums=(
'6f9e67d2c9b9ac77f79c46bd6af3779e4e5a0d45fe2fc30913bc588e8e23ab9bcbeda311f5fb53f5f277ba0711c6f3ce53e5d9b849228e9d88dbf816764f0069'
'SKIP' 'SKIP' 'SKIP' 'SKIP' 'SKIP' 'SKIP'
)
b2sums=(
'ddfdf65d171c14119fefdf6505fb77bce2803ef2811615c638abc292206e7ca6d2cc880ffc3bbd3381c50116470584c4905780c4c51c5686b571bb9723a3490c'
'SKIP' 'SKIP' 'SKIP' 'SKIP' 'SKIP' 'SKIP'
)
# eof
|