blob: 0b4eae417bc5e8c3a2bf9736579dbbc33c72b202 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
|
# Maintainer: Klaus Alexander Seistrup <klaus@seistrup.dk>
# -*- sh -*-
pkgname='simplex-chat-bin'
_pkgname="${pkgname%%-bin}"
pkgver=4.2.2
pkgrel=1
pkgdesc='A 100% private-by-design chat platform (pre-compiled)'
arch=('x86_64')
_platform='ubuntu-20_04-x86-64'
url='https://simplex.chat/'
_rawurl='https://raw.githubusercontent.com/simplex-chat/simplex-chat/master'
source=(
"$_pkgname-$pkgver::https://github.com/$_pkgname/$_pkgname/releases/download/v$pkgver/$_pkgname-$_platform"
"$_rawurl/PRIVACY.md"
"$_rawurl/README.md"
"$_rawurl/docs/CLI.md"
"$_rawurl/docs/SIMPLEX.md"
"$_rawurl/docs/SQL.md"
"$_rawurl/scripts/message_views.sql"
)
license=('AGPL3')
depends=(
'gmp'
'openssl-1.1'
'zlib'
)
provides=('simplex-chat')
conflicts=('simplex-chat')
package() {
cd "$srcdir" || exit 1
install -Dm0755 "$_pkgname-$pkgver" "$pkgdir/usr/bin/$_pkgname"
for doc in {PRIVACY,README,CLI,SIMPLEX,SQL}.md; do
install -Dm0644 "$doc" "$pkgdir/usr/share/doc/$_pkgname/$doc"
done
install -Dm0644 message_views.sql "$pkgdir/usr/share/doc/$_pkgname/message_views.sql"
}
sha256sums=(
'16826407439bf76d98d1993ebbacb5a2e3cce1a945fdfacb3259ad4f0f26a0ef'
'SKIP' 'SKIP' 'SKIP' 'SKIP' 'SKIP' 'SKIP'
)
sha512sums=(
'bc7eaa19f602059e03734ce5884fe12b9b30f29765b814d6e5c55060b6d790df57bd4552482add077093152b293d57be7a9f3fc2029ce8abce40d5cc7227e203'
'SKIP' 'SKIP' 'SKIP' 'SKIP' 'SKIP' 'SKIP'
)
b2sums=(
'5d0da5250209d7953d28a169efbefba372dc95e0eaebf9c3d1156181e8413134edb55daf7146115175d35112ce60a642b46c777e3cb829fdf5594b9214c07eef'
'SKIP' 'SKIP' 'SKIP' 'SKIP' 'SKIP' 'SKIP'
)
# eof
|