blob: bfd91cc3f8079e5d0a97aa0e38ae96ade8c01f1f (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
|
# Maintainer: everyx <lunt.luo#gmail.com>
pkgname=sing-box
pkgver=1.1
pkgrel=3
pkgdesc='The universal proxy platform.'
arch=('x86_64' 'i686')
url='https://sing-box.sagernet.org/'
license=('GPL3')
makedepends=('go')
source=("$pkgname-$pkgver.tar.gz::https://github.com/SagerNet/sing-box/archive/v$pkgver.tar.gz")
sha256sums=('156d717b46eec252a4a1042b41a3aa5c0fbd5ab684de4f535ceedb542fb99ef6')
conflicts=("${pkgname}-git" "${pkgname}-beta")
optdepends=('sing-geosite: sing-geosite database'
'sing-geoip: sing-geoip database')
backup=('etc/sing-box/config.json')
_tags=with_gvisor,with_quic,with_wireguard,with_utls,with_clash_api
build(){
cd $pkgname-$pkgver
export CGO_CPPFLAGS="${CPPFLAGS}"
export CGO_CFLAGS="${CFLAGS}"
export CGO_CXXFLAGS="${CXXFLAGS}"
export CGO_LDFLAGS="${LDFLAGS}"
go build \
-v \
-trimpath \
-buildmode=pie \
-mod=readonly \
-modcacherw \
-tags "$_tags" \
-ldflags '-linkmode=external -w -s' \
./cmd/sing-box
sed -i '/^\[Service\]$/a User=sing-box' release/config/${pkgname}*.service
echo 'u sing-box - "Sing-box Service" - -' > release/config/${pkgname}.sysusers
}
package() {
cd $pkgname-$pkgver
install -Dm755 "${pkgname}" -t "${pkgdir}/usr/bin"
install -Dm644 "LICENSE" -t "${pkgdir}/usr/share/licenses/${pkgname}"
install -Dm644 "release/config/config.json" -t "${pkgdir}/etc/${pkgname}"
install -Dm644 "release/config/${pkgname}.service" -t "${pkgdir}/usr/lib/systemd/system"
install -Dm644 "release/config/${pkgname}@.service" -t "${pkgdir}/usr/lib/systemd/system"
install -Dm644 "release/config/${pkgname}.sysusers" "${pkgdir}/usr/lib/sysusers.d//${pkgname}.conf"
}
|