blob: dd2b124515d3e3b91e07fa29afc2fadec63b52d8 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
|
# Maintainer: everyx <lunt.luo#gmail.com>
pkgname=sing-box
pkgver=1.5.3
pkgrel=1
pkgdesc='The universal proxy platform.'
arch=('i686' 'pentium4' 'x86_64' 'arm' 'armv7h' 'armv6h' 'aarch64')
url='https://sing-box.sagernet.org/'
license=('GPL3 with name use or association addition')
makedepends=('go')
source=("$pkgname-$pkgver.tar.gz::https://github.com/SagerNet/sing-box/archive/v$pkgver.tar.gz")
sha256sums=('e050f8a588d92547ba277fc8980af8ede544c345684c20e4b008fbc1b1371fb8')
conflicts=("$pkgname-git" "$pkgname-beta")
optdepends=('sing-geosite: sing-geosite database'
'sing-geoip: sing-geoip database')
backup=("etc/$pkgname/config.json")
_tags=with_gvisor,with_quic,with_wireguard,with_utls,with_reality_server,with_clash_api
build(){
cd "$pkgname-$pkgver"
export CGO_CPPFLAGS="$CPPFLAGS"
export CGO_CFLAGS="$CFLAGS"
export CGO_CXXFLAGS="$CXXFLAGS"
export CGO_LDFLAGS="$LDFLAGS"
go build \
-v \
-trimpath \
-buildmode=pie \
-mod=readonly \
-modcacherw \
-tags "$_tags" \
-ldflags "
-X \"github.com/sagernet/sing-box/constant.Version=$pkgver\"
-s -w -buildid= -linkmode=external" \
./cmd/sing-box
sed -i "/^\[Service\]$/a StateDirectory=$pkgname" release/config/$pkgname.service
sed -i "/^\[Service\]$/a StateDirectory=$pkgname-%i" release/config/$pkgname@.service
sed -i "/^\[Service\]$/a User=$pkgname" release/config/$pkgname*.service
echo "u $pkgname - \"Sing-box Service\" - -" > "release/config/$pkgname.sysusers"
install -d completions
go run ./cmd/sing-box completion bash > completions/bash
go run ./cmd/sing-box completion fish > completions/fish
go run ./cmd/sing-box completion zsh > completions/zsh
}
package() {
cd "$pkgname-$pkgver"
install -Dm644 LICENSE -t "$pkgdir/usr/share/licenses/$pkgname"
install -Dm755 "$pkgname" -t "$pkgdir/usr/bin"
install -Dm644 "release/config/config.json" -t "$pkgdir/etc/$pkgname"
install -Dm644 "release/config/$pkgname.service" -t "$pkgdir/usr/lib/systemd/system"
install -Dm644 "release/config/$pkgname@.service" -t "$pkgdir/usr/lib/systemd/system"
install -Dm644 "release/config/$pkgname.sysusers" "$pkgdir/usr/lib/sysusers.d/$pkgname.conf"
install -Dm644 completions/bash "${pkgdir}/usr/share/bash-completion/completions/${pkgname}.bash"
install -Dm644 completions/fish "${pkgdir}/usr/share/fish/vendor_completions.d/${pkgname}.fish"
install -Dm644 completions/zsh "${pkgdir}/usr/share/zsh/site-functions/_${pkgname}"
}
|