blob: 0f9540becbef724a199327eb359e967a409a730e (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
|
# Maintainer: Maciej Sieczka <msieczka at sieczka dot org>
pkgname='singularity-container'
pkgver='3.5.2'
pkgrel='1'
pkgdesc='Container platform focused on supporting "Mobility of Compute".'
arch=('i686' 'x86_64')
url='https://www.sylabs.io/singularity/'
license=('BSD')
makedepends=('go' 'dep')
depends=('squashfs-tools' 'libseccomp')
source=("https://github.com/sylabs/singularity/releases/download/v${pkgver}/singularity-${pkgver}.tar.gz")
noextract=("singularity-${pkgver}.tar.gz")
md5sums=('1dfaec2ea37775065093fa6f679b87f6')
prepare() {
export GOPATH="${srcdir}/singularity"
mkdir -p "${GOPATH}/src/github.com/sylabs"
tar -zxf singularity-${pkgver}.tar.gz -C "${GOPATH}/src/github.com/sylabs"
}
build() {
export GOPATH="${srcdir}/singularity"
cd "${GOPATH}/src/github.com/sylabs/singularity"
./mconfig --prefix=/usr --sysconfdir=/etc --localstatedir=/var --sbindir=/usr/bin
cd builddir
make
}
package() {
export GOPATH="${srcdir}/singularity"
cd "${GOPATH}/src/github.com/sylabs/singularity/builddir"
make DESTDIR="${pkgdir}" install
}
|