blob: aa162de0dbacc398a48093838cfaee794c1dbe28 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
|
# Maintainer: honjow
pkgname=sk-chos-tool-git
_pkgname=sk-chos-tool
pkgver=r313.bbce840
pkgrel=1
pkgdesc="A custom configs tool for sk-chimeros"
arch=('any')
url="https://github.com/honjow/sk-holoiso-config.git"
license=('MIT')
makedepends=('git')
depends=('python-gobject' 'gtk3' 'openssl' 'expect' 'efibootmgr')
provides=(sk-chos-tool)
conflicts=(sk-chos-tool)
replaces=(sk-chos-tool)
source=("git+$url")
sha256sums=('SKIP')
options=(!strip)
install=sk-chos-tool.install
backup=('etc/sk-chos-tool/github_cdn.conf')
pkgver() {
cd "$srcdir/sk-holoiso-config"
printf "r%s.%s" "$(git rev-list --count HEAD)" "$(git rev-parse --short HEAD)"
}
package() {
source_dir="${srcdir}/sk-holoiso-config/src/chimeraos"
install -dm755 "${pkgdir}/usr/share/${_pkgname}"
# bin
install -dm755 "${pkgdir}/usr/bin/"
install -m755 -t "${pkgdir}/usr/bin/" "${source_dir}/bin"/*
# icon
install -dm755 "${pkgdir}/usr/share/icons/hicolor/scalable/apps"
install -m644 -t "${pkgdir}/usr/share/icons/hicolor/scalable/apps" "${source_dir}/icon"/*.svg
# conf
install -dm755 "${pkgdir}/etc/${_pkgname}"
install -m644 -t "${pkgdir}/etc/${_pkgname}" "${source_dir}/etc/${_pkgname}"/*.conf
# service
install -dm755 "${pkgdir}/usr/lib/systemd/system"
install -m644 -t "${pkgdir}/usr/lib/systemd/system" "${source_dir}/systemd/system"/*
# user service
install -dm755 "${pkgdir}/usr/lib/systemd/user"
install -m644 -t "${pkgdir}/usr/lib/systemd/user" "${source_dir}/systemd/user"/*
# 主程序
install -dm755 "${pkgdir}/usr/share/${_pkgname}/pages"
install -dm755 "${pkgdir}/usr/share/${_pkgname}/scripts"
install -m755 -t "${pkgdir}/usr/share/${_pkgname}/pages" "${source_dir}/main/pages"/*
install -m755 -t "${pkgdir}/usr/share/${_pkgname}" "${source_dir}/main"/*.*
install -m755 -t "${pkgdir}/usr/share/${_pkgname}/scripts" "${source_dir}/main/scripts"/*.*
# 主程序入口
ln -s "/usr/share/${_pkgname}/sk-chos-tool.py" "${pkgdir}/usr/bin/sk-chos-tool"
# 程序图标
install -Dm644 "${source_dir}/sk-chos-tool-command.desktop" "${pkgdir}/usr/share/applications/sk-chos-tool-command.desktop"
install -Dm644 "${source_dir}/sk-chos-tool.desktop" "${pkgdir}/usr/share/applications/sk-chos-tool.desktop"
}
|