blob: 19f16d6b9c937e0626df935c46f1c49ed033754e (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
|
# Maintainer: Fredy García <frealgagu at gmail dot com>
# Maintainer: Maxim Baz <${pkgname} at maximbaz dot com>
# Contributor: Stefan Cocora <stefan dot cocora at gmail dot com>
pkgname=skaffold
pkgver=1.14.0
pkgrel=1
pkgdesc="A command line tool that facilitates continuous development for Kubernetes applications"
arch=("x86_64")
url="https://github.com/GoogleContainerTools/${pkgname}"
license=("Apache")
depends=("docker" "kubectl")
makedepends=("go")
optdepends=(
"google-cloud-sdk: To use GKE"
"minikube: To use Minikube"
)
source=(
"${pkgname}-${pkgver}.tar.gz::https://github.com/GoogleContainerTools/${pkgname}/archive/v${pkgver}.tar.gz"
"build_info.patch"
)
sha256sums=(
"25e3099f6c444483729808bc3ac5f35d6fc40ad1a648020c3c591de972ac8611"
"e90797011d2f79c79a6b184a5e9c35c4e5c582622d075b0022675b96fccefc46")
_commit="4b3ca59af505c4ab5d5b6960a194e1f6887018f8"
prepare() {
cd "${srcdir}/${pkgname}-${pkgver}"
patch -Np1 -i "${srcdir}/build_info.patch"
rm -rf "${srcdir}/gopath"
mkdir -p "${srcdir}/gopath/bin"
mkdir -p "${srcdir}/gopath/src/github.com/GoogleContainerTools"
ln -rTsf "${srcdir}/${pkgname}-${pkgver}" "${srcdir}/gopath/src/github.com/GoogleContainerTools/${pkgname}"
}
build() {
cd "${srcdir}/gopath/src/github.com/GoogleContainerTools/${pkgname}"
export GOPATH="${srcdir}/gopath"
export PATH="${PATH}:${GOPATH}/bin"
export VERSION="v${pkgver}"
export COMMIT="${_commit}"
export TREE_STATE="clean"
export CGO_CPPFLAGS="${CPPFLAGS}"
export CGO_CFLAGS="${CFLAGS}"
export CGO_CXXFLAGS="${CXXFLAGS}"
export CGO_LDFLAGS="${LDFLAGS}"
export GOFLAGS="-buildmode=pie -mod=readonly -modcacherw -x -v"
make install
# To avoid issues deleting directories next time
go clean --modcache
}
package() {
install -Dm755 "${srcdir}/gopath/bin/${pkgname}" "${pkgdir}/usr/bin/${pkgname}"
}
|