summarylogtreecommitdiffstats
path: root/PKGBUILD
blob: f6335fad1e712925fa4d9a266f08486e80bc7b21 (plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
# Maintainer: Gustavo Alvarez <sl1pkn07@gmail.com>

pkgname=skanlite-git
pkgver=1.1.0.r217.ff1f58b
pkgrel=1
pkgdesc="A Lite image scanning application. (GIT version)"
arch=('i686' 'x86_64')
url='http://www.kde.org/applications/graphics/skanlite'
license=('GPL')
depends=('libksane'
         'kio'
         )
makedepends=('extra-cmake-modules'
             'kdoctools'
             'git'
             'cmake'
             'python'
             )
conflicts=('skanlite'
           'skanlite-frameworks-git'
           )
source=('git://anongit.kde.org/skanlite')
sha1sums=('SKIP')

pkgver() {
  cd skanlite
  _ver="$(cat CMakeLists.txt | grep -m1 SKANLITE_VERSION_STRING | cut -d '"' -f2)"
  echo "${_ver}.r$(git rev-list --count HEAD).$(git rev-parse --short HEAD)"
}

prepare() {
  mkdir -p build
}

build() {
  cd build
  cmake ../skanlite \
    -DCMAKE_BUILD_TYPE=Release \
    -DCMAKE_INSTALL_PREFIX=/usr \
    -DLIB_INSTALL_DIR=lib \
    -DKDE_INSTALL_USE_QT_SYS_PATHS=ON \
    -DBUILD_TESTING=OFF
  make
}

package() {
  make -C build DESTDIR="${pkgdir}" install
}