PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56

# Maintainer: liixini <https://github.com/liixini>
pkgname=skwd-daemon
pkgver=r85.36f165a
pkgrel=1
pkgdesc='Daemon for Skwd Shell, a collection of Quickshell programs and widgets'
arch=('x86_64')
url='https://github.com/liixini/skwd-daemon'
license=('MIT')
makedepends=('cargo' 'gcc' 'clang' 'pkgconf' 'patchelf' 'ffmpeg' 'alsa-lib' 'libpulse' 'wayland' 'wayland-protocols' 'mesa')
depends=('gcc-libs' 'imagemagick' 'ffmpeg' 'alsa-lib' 'libpulse' 'wayland' 'mesa')
options=('!debug' '!lto')
optdepends=(
  'ollama: local LLM for automated wallpaper tagging'
  'steamcmd: Steam Workshop Wallpaper Engine downloads when the Steam client is not running'
  'linux-wallpaperengine: Wallpaper Engine scene rendering'
)
install="${pkgname}.install"
source=("${pkgname}::git+https://github.com/liixini/skwd-daemon.git")
sha256sums=('SKIP')

pkgver() {
  cd "$pkgname"
  printf "r%s.%s" "$(git rev-list --count HEAD)" "$(git rev-parse --short HEAD)"
}

prepare() {
  cd "$pkgname"
  export RUSTUP_TOOLCHAIN=stable
  cargo fetch --locked --target "$(rustc -vV | sed -n 's/host: //p')"
}

build() {
  cd "$pkgname"
  export RUSTUP_TOOLCHAIN=stable
  export CARGO_TARGET_DIR=target
  export CFLAGS="${CFLAGS//-flto*([^ ])/}"
  export LIBCLANG_PATH=/usr/lib
  cargo build --frozen --release
}

package() {
  cd "$pkgname"

  install -Dm755 target/release/skwd-daemon "$pkgdir/usr/bin/skwd-daemon"
  install -Dm755 target/release/skwd "$pkgdir/usr/bin/skwd"
  install -Dm755 target/release/skwd-paper "$pkgdir/usr/bin/skwd-paper"
  install -Dm755 target/release/skwd-paper-still "$pkgdir/usr/bin/skwd-paper-still"

  install -Dm644 target/release/libsteam_api.so "$pkgdir/usr/lib/skwd-daemon/libsteam_api.so"
  patchelf --set-rpath '$ORIGIN/../lib/skwd-daemon' "$pkgdir/usr/bin/skwd-daemon"

  install -Dm644 data/skwd-daemon.service "$pkgdir/usr/lib/systemd/user/skwd-daemon.service"
  install -Dm644 data/host/shell.qml "$pkgdir/usr/share/skwd/skwd-daemon/host/shell.qml"

  install -Dm644 LICENSE "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
}