blob: ae5a057ec0364a69380fbddc22c21af59e4ac198 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
|
# Maintainer: mark.blakeney at bullet-systems dot net
# Original Maintainer: Jameson Pugh <imntreal@gmail.com>
_pkgname=skypeforlinux
pkgname=$_pkgname-preview-bin
pkgver=8.37.76.92
pkgrel=1
pkgdesc="Skype for Linux - Preview/Insider Version"
arch=("x86_64")
url="http://www.skype.com"
license=("custom")
depends=("gtk3" "libxss" "gconf" "alsa-lib" "libxtst" "libsecret" "nss" "glibc>=2.28-4")
optdepends=("gnome-keyring")
makedepends=("asar")
conflicts=("$_pkgname" "$_pkgname-bin" "$_pkgname-stable-bin" "$_pkgname-beta-bin" "skype")
provides=("$_pkgname" "skype")
replaces=("$_pkgname-bin")
source=(
"https://repo.skype.com/deb/pool/main/s/$_pkgname/${_pkgname}_${pkgver}_amd64.deb"
)
sha256sums=('e9101984c4164a13db22218d94db3ca998121dfcbc5295681b828ee33ea017bb')
package() {
tar -xJC "$pkgdir" -f data.tar.xz
install -d "$pkgdir/usr/share/licenses/$pkgname"
mv "$pkgdir/usr/share/$_pkgname/LICENSES.chromium.html" \
"$pkgdir/usr/share/licenses/$pkgname/"
rm -rf "$pkgdir/opt"
# Replace all 16px tray icons with 32px.
_p="/usr/share/skypeforlinux/resources"
cd "$pkgdir/$_p"
asar extract app.asar _tmp
cd _tmp/images/tray
find . -iname '*@2x.png' | while read f; do
cp $f ${f//@2x/}
done
cd "$pkgdir/$_p"
asar pack _tmp app.asar
rm -rf _tmp
}
# vim:set ts=2 sw=2 et:
|