PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38

# Maintainer: mia <mia@mia.jetzt>

pkgname='skytable-bin'
pkgver='0.8.1'
pkgrel='1'
pkgdesc='Skytable is a modern NoSQL database powered by BlueQL'
arch=('x86_64')
url='https://skytable.io'
license=('AGPL-3.0-only')
provides=('skytable')
_repo='https://github.com/skytable/skytable'
_pkgfile="skytable-v${pkgver}-${arch}-linux-gnu.deb"
source=("${_repo}/releases/download/v${pkgver}/${_pkgfile}"
        'skytable.tmpfiles'
        'skytable.sysusers')
noextract=("${_pkgfile}")
sha256sums=('2a7f9844f320048e39a76a364c2f024415cb8d3e6d086aa71a118a3e48b4c617'
            '1707e36c4613020bdbf2a0a33afd130d30b4e0b615831ba06eaadbe865e86156'
            'd04ba945687bd3c0dd8ccfec8dbb06808e89169b11225aedf6df85373058330d')

prepare() {
    ar x "${_pkgfile}" data.tar.xz
    tar xf data.tar.xz
}

package() {
    install -Dm 755 "${srcdir}/usr/bin/skyd" "${pkgdir}/usr/bin/skyd"
    install -Dm 755 "${srcdir}/usr/bin/skysh" "${pkgdir}/usr/bin/skysh"
    install -Dm 755 "${srcdir}/usr/bin/sky-bench" "${pkgdir}/usr/bin/sky-bench"

    install -Dm 644 "skytable.tmpfiles" "${pkgdir}/usr/lib/tmpfiles.d/skytable.conf"
    install -Dm 644 "skytable.sysusers" "${pkgdir}/usr/lib/sysusers.d/skytable.conf"
    install -Dm 644 "${srcdir}/usr/share/doc/skytable/copyright" "${pkgdir}/usr/share/doc/skytable/copyright"

    install -Dm 644 "${srcdir}/etc/systemd/system/skyd.service" "${pkgdir}/etc/systemd/system/skyd.service"

    install -Dm 644 "${srcdir}/var/lib/skytable/config.yaml.tmp" "${pkgdir}/var/lib/skytable/config.yaml"
}