blob: bc2dfe2353d3baaa307b97fde72c0fb0e143b98e (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
|
# Maintainer: Chris Speck <chris.speck(at)annalise(dot)ai>
pkgname=slack-desktop-wayland
_original_pkgname=slack-desktop
pkgver=4.29.149
pkgrel=2
pkgdesc="Slack Desktop (Beta) for Linux with Wayland Support"
arch=('x86_64')
url="https://slack.com/downloads"
license=('custom')
depends=('gtk3' 'libsecret' 'libxss' 'nss' 'pipewire' 'xdg-utils' 'xdg-desktop-portal')
optdepends=('libappindicator-gtk3: Systray indicator support'
'org.freedesktop.secrets: Keyring password store support'
'xdg-desktop-portal-gnome: xdg-desktop-portal support for GNOME'
'xdg-desktop-portal-gtk: xdg-desktop-portal support for GNOME and GTK'
'xdg-desktop-portal-kde: xdg-desktop-portal support for KDE'
'xdg-desktop-portal-lxqt: xdg-desktop-portal support for LXQt'
'xdg-desktop-portal-wlr: xdg-desktop-portal support for wlroots-based Wayland compositors'
)
source=("https://downloads.slack-edge.com/releases/linux/${pkgver}/prod/x64/${_original_pkgname}-${pkgver}-amd64.deb"
"${_original_pkgname}.patch")
noextract=("${_original_pkgname}-${pkgver}-amd64.deb")
b2sums=('1d36947c5b4da0a2e301b3510dff9e5d3dbc6a3a2f0411980792984a497578d239dbc90dfb6af5cfe6d87dbcb7c3acac3b79c86daf6d58a4a9e69223472447f6'
'a2a20375b24bff50ea77520b33fa53388bc53bf797772fca7fb507a37175ba48b1dd13b4b3fbdcc1e0f21dbd99d99c7a62470a9c282a6b39df7dc610299a7828')
provides=('slack-desktop')
conflicts=('slack-desktop' 'slack-electron')
package() {
bsdtar -O -xf "slack-desktop-${pkgver}"*.deb data.tar.xz | bsdtar -C "${pkgdir}" -xJf -
# Fix hardcoded icon path in .desktop file
patch -d "${pkgdir}" -p1 <"${_original_pkgname}".patch
# Permission fix
find "${pkgdir}" -type d -exec chmod 755 {} +
# Remove all unnecessary stuff
rm -rf "${pkgdir}/etc"
rm -rf "${pkgdir}/usr/lib/slack/src"
rm -rf "${pkgdir}/usr/share/lintian"
rm -rf "${pkgdir}/usr/share/doc"
# Move license
install -dm755 "${pkgdir}/usr/share/licenses/${_original_pkgname}"
mv "${pkgdir}/usr/lib/slack/LICENSE" "${pkgdir}/usr/share/licenses/${_original_pkgname}"
ln -s "/usr/share/licenses/${_original_pkgname}/LICENSE" "${pkgdir}/usr/lib/slack/LICENSE"
}
|