blob: ab4e35cd9a420488fda2b639819d8473763f97ad (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
|
# Maintainer: Luis Martinez <luis dot martinez at disroot dot org>
# Maintainer: Moon Sungjoon <sumoon at seoulsaram dot org>
# Contributor: Yurii Kolesnykov <root@yurikoles.com>
pkgname=slack-electron
pkgver=4.26.1
pkgrel=1
pkgdesc="Slack Desktop (Beta) for Linux, using the system Electron package"
arch=('x86_64')
url="https://slack.com/downloads"
license=('custom:proprietary')
depends=('electron17')
optdepends=('libappindicator-gtk3: for notification indicator in the status bar on GNOME')
provides=("slack-desktop")
conflicts=("slack-desktop")
source=("$pkgname-$pkgver.deb::https://downloads.slack-edge.com/releases/linux/$pkgver/prod/x64/slack-desktop-$pkgver-amd64.deb"
'slack.sh')
sha256sums=('c13fa42fa7f63afbcffb315dd4c2bb626f98d680be86483543f7db78bd63835b'
'eddf0c5c6d50c01023a5095b591d4bfd99dc37d610bf494ed004b9212326a09d')
prepare() {
bsdtar -xf data.tar.xz
# Enable slack silent mode and fix icon
sed -ri \
-e 's|^(Exec=.+/slack)(.+)|\1 -s\2|' \
-e 's/^Icon=.+slack\.png/Icon=slack/' \
"usr/share/applications/slack.desktop"
}
package() {
install -D "slack.sh" "$pkgdir/usr/bin/slack"
install -d "$pkgdir/usr/lib/slack/"
cp -a --no-preserve=ownership usr/lib/slack/resources/* "$pkgdir/usr/lib/slack/"
install -Dm644 "usr/share/applications/slack.desktop" -t "$pkgdir/usr/share/applications"
install -Dm644 "usr/share/pixmaps/slack.png" -t "$pkgdir/usr/share/pixmaps"
install -Dm644 "usr/lib/slack/LICENSE" -t "$pkgdir/usr/share/licenses/$pkgname/"
}
|