blob: 6bad6e4540050dcdca5616e9970053e4fd9e9597 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
|
# Maintainer: Luis Martinez <luis dot martinez at disroot dot org>
# Contributor: Yurii Kolesnykov <root@yurikoles.com>
pkgname=slack-electron
pkgver=4.20.0
pkgrel=1
pkgdesc="Slack Desktop (Beta) for Linux, using the system Electron package"
arch=('x86_64')
url="https://slack.com/downloads"
license=('custom:proprietary')
depends=('electron')
optdepends=('libappindicator-gtk3: for notification indicator in the status bar on GNOME')
provides=("slack-desktop")
conflicts=("slack-desktop")
source=("https://downloads.slack-edge.com/releases/linux/$pkgver/prod/x64/slack-desktop-$pkgver-amd64.deb"
'slack.sh')
sha256sums=('b08207389246837536ea769425d458411c08dc6802ffaae9249092e387461ce5'
'4db11d083626a561129ca40e9cce7cc613c42223f138bb0136c62064c57471fd')
prepare() {
bsdtar -xf data.tar.xz
# Enable slack silent mode and fix icon
sed -ri \
-e 's|^(Exec=.+/slack)(.+)|\1 -s\2|' \
-e 's/^Icon=.+slack\.png/Icon=slack/' \
"usr/share/applications/slack.desktop"
}
package() {
install -Dm755 "slack.sh" "$pkgdir/usr/bin/slack"
install -dm755 "$pkgdir/usr/lib/slack/"
cp -a --no-preserve=ownership usr/lib/slack/resources/* "$pkgdir/usr/lib/slack/"
install -Dm644 "usr/share/applications/slack.desktop" -t "$pkgdir/usr/share/applications"
install -Dm644 "usr/share/pixmaps/slack.png" -t "$pkgdir/usr/share/pixmaps"
install -Dm644 "usr/lib/slack/LICENSE" -t "$pkgdir/usr/share/licenses/$pkgname/"
}
|