blob: 49b9f03c18e873756f2ff0d40bba6a9e9c9dbd5a (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
|
# Maintainer: Chocobo1 <chocobo1 AT archlinux DOT net>
pkgname=sleuthkit-git
pkgver=4.12.1.r33.g07e100662
pkgrel=1
pkgdesc="A library and collection of command line digital forensics tools"
arch=('i686' 'x86_64')
url="https://www.sleuthkit.org/sleuthkit/"
license=('custom')
depends=('gcc-libs' 'libewf' 'sqlite')
makedepends=('git')
optdepends=('perl')
provides=("sleuthkit=$pkgver")
conflicts=('sleuthkit')
options=('staticlibs')
source=("git+https://github.com/sleuthkit/sleuthkit.git")
sha256sums=('SKIP')
pkgver() {
cd "sleuthkit"
_tag=$(git tag -l --sort -v:refname | grep -E '^sleuthkit-[0-9\.]+$' | head -n1)
_rev=$(git rev-list --count $_tag..HEAD)
_hash=$(git rev-parse --short HEAD)
printf "%s.r%s.g%s" "$_tag" "$_rev" "$_hash" | sed 's/^sleuthkit-//'
}
build() {
cd "sleuthkit"
./bootstrap
./configure \
--prefix="/usr"
make
}
check() {
cd "sleuthkit"
#make check
}
package() {
cd "sleuthkit"
make DESTDIR="$pkgdir" install
install -Dm644 licenses/* -t "$pkgdir/usr/share/licenses/sleuthkit"
}
|