blob: f9feee483bbdf63b11ed17d16cb37bd367ebd1dd (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
|
# Maintainer: Vitalii Kuzhdin <vitaliikuzhdin@gmail.com>
pkgname="slsa-verifier"
pkgver=2.7.1
pkgrel=1
pkgdesc="Verify provenance from SLSA compliant builders"
arch=('aarch64' 'x86_64')
url="https://github.com/slsa-framework/${pkgname}"
license=('MIT')
depends=(
'glibc'
)
makedepends=(
'go'
'git'
)
_pkgsrc="${url##*/}"
source=("${_pkgsrc}::git+${url}.git#tag=v${pkgver}")
sha256sums=('60cc48ee418a0634e1abe46e74cce37067868c7cc4fe4629523012de5006b43f')
b2sums=('34ce439926d31466ef56864ff5e60c24bdf354cc703328b44ae06085ecdf574b3acb91060ddcef2fd316faa6b2c9e144dce272db4d7de0b9f48cccb320a37959')
prepare() {
export GOMODCACHE="${srcdir}/go-mod-cache"
cd "${srcdir}/${_pkgsrc}"
go mod download -x
chmod -R ug+Xwr "${GOMODCACHE}"
mkdir -p "build"
}
build() {
export CGO_CPPFLAGS="${CPPFLAGS}"
export CGO_CFLAGS="${CFLAGS}"
export CGO_CXXFLAGS="${CXXFLAGS}"
export CGO_LDFLAGS="${LDFLAGS}"
export GOCACHE="${srcdir}/go-cache"
export GOMODCACHE="${srcdir}/go-mod-cache"
export GOFLAGS="-buildmode=pie -trimpath -ldflags=-linkmode=external -mod=readonly -modcacherw"
cd "${srcdir}/${_pkgsrc}"
go build -v -o "build/${pkgname}" ./"cli/${pkgname}"
}
check() {
cd "${srcdir}/${_pkgsrc}"
go test ./...
}
package() {
cd "${srcdir}/${_pkgsrc}"
install -vDm755 "build/${pkgname}" "${pkgdir}/usr/bin/${pkgname}"
install -vDm644 "README.md" "${pkgdir}/usr/share/doc/${pkgname}/README.md"
install -vDm644 "LICENSE" "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
}
|