blob: a5e190f3b20b2665bcf88b31fcac78940a2b36cd (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
|
# Maintainer: Mark Wagie <mark dot wagie at proton dot me>
# Contributor: Igor Dyatlov <dyatlov.igor@protonmail.com>
# Contributor: Eli Schwartz
pkgname=smile
pkgver=2.9.5
pkgrel=1
pkgdesc="An emoji picker with custom tags support"
arch=('any')
url="https://smile.mijorus.it"
license=('GPL-3.0-or-later')
depends=('dbus-python' 'emoji-font' 'libadwaita' 'python-gobject')
makedepends=('meson')
checkdepends=('appstream-glib')
optdepends=('wl-clipboard: Automatically paste emojis (Wayland)'
'xdotool: Automatically paste emojis (X11)')
conflicts=("$pkgname-emoji-picker")
source=("$pkgname-$pkgver.tar.gz::https://github.com/mijorus/smile/archive/refs/tags/$pkgver.tar.gz")
sha256sums=('62b4cee49957182abdafd686d5fbdbc0553ff35eb61c702306e628e58e0af221')
prepare() {
cd "$pkgname-$pkgver"
# This is not a Flatpak
sed -i 's|flatpak run {self.application_id}|/usr/bin/smile|g' src/Settings.py
}
build() {
arch-meson "$pkgname-$pkgver" build
meson compile -C build
}
check() {
meson test -C build --print-errorlogs || :
}
package() {
meson install -C build --destdir "$pkgdir"
rm -v "$pkgdir/usr/share/icons/hicolor/scalable/actions/meson.build"
rm -v "$pkgdir/usr/share/$pkgname/assets/meson.build"
}
|