PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41

# Maintainer: Mark Wagie <mark dot wagie at proton dot me>
pkgname=smooth-git
pkgver=0.9.10.r38.gd8418a2
pkgrel=1
pkgdesc="An object oriented C++ class library"
arch=('x86_64')
url="http://www.smooth-project.org"
license=('Artistic-2.0')
depends=(
  'curl'
  'fribidi'
  'gtk3'
  'libjpeg-turbo'
  'libxml2'
)
makedepends=('git')
provides=("${pkgname%-git}" 'libsmooth-0.9.so=0')
conflicts=("${pkgname%-git}")
source=('git+https://github.com/enzo1982/smooth.git')
sha256sums=('SKIP')

pkgver() {
  cd "${pkgname%-git}"
  git describe --long --tags --abbrev=7 | sed 's/^v//;s/\([^-]*-g\)/r\1/;s/-/./g'
}

prepare() {
  cd "${pkgname%-git}"
  find . -type f -exec sed -i 's|/usr/local|/usr|g' {} \;
}

build() {
  cd "${pkgname%-git}"
  make
}

package() {
  cd "${pkgname%-git}"
  make DESTDIR="$pkgdir/" install
  ln -s "/usr/lib/libsmooth-${pkgver%.*.r*}.so" "${pkgdir}/usr/lib/libsmooth.so"
}