blob: 3f7faf9e5417dbf87e7ad5fe4470bd7b67155866 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
|
# Maintainer: Philipp A. <flying-sheep@web.de>
# Contributor: Kyle Meyer <kyle@kyleam.com>
pkgname=snakemake
pkgver=5.6.0
pkgrel=1
pkgdesc='Python-based language and execution environment for GNU Make-like workflows'
arch=(any)
url='https://snakemake.readthedocs.io'
depends=(
python python-requests python-wrapt python-ratelimiter
python-configargparse python-yaml python-appdirs
python-docutils python-datrie python-jsonschema
)
makedepends=(python-setuptools python-gitpython)
optdepends=(
'graphviz: For DAG visualization'
'python-jinja: For report generation'
'python-networkx: For report generation'
'python-biopython: For GenBank/NCBI Entrez support'
'python-easywebdav: For WebDAV support'
'python-pysftp: For SFTP support'
'python-boto3: For AWS support'
'python-moto: For AWS support'
'python-dropbox: For Dropbox support'
'python-ftputil: For FTP support'
'xrootd: For XRootD support'
'python-psutil: For benchmarking'
)
license=(MIT)
source=("https://files.pythonhosted.org/packages/source/${pkgname::1}/$pkgname/$pkgname-$pkgver.tar.gz")
sha256sums=('65b944bcf06fd31b5da7430a6012a542c4c3c05a822b92ca218f2406eabd2c24')
build() {
cd "$srcdir/$pkgname-$pkgver"
python setup.py build
}
package() {
cd "$srcdir/$pkgname-$pkgver"
python setup.py install --skip-build -O1 --root="$pkgdir" || exit 1
local pyver=$(python -c 'import sys; print("{}.{}".format(*sys.version_info[:2]))')
install -d "$pkgdir/etc/bash_completion.d"
PYTHONPATH="$pkgdir/usr/lib/python$pyver/site-packages:$PYTHONPATH" \
"$pkgdir/usr/bin/snakemake" --bash-completion >"$pkgdir/etc/bash_completion.d/snakemake"
}
|