blob: c7c84b974f150d265dba0d490823eff6c9f633cc (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
|
# Maintainer: KokaKiwi <kokakiwi+aur [at] kokakiwi [dot] net>
pkgname=snowflake-pt-proxy
pkgver=2.8.1
pkgrel=1
pkgdesc="Snowflake is a pluggable transport that proxies traffic through temporary proxies using WebRTC (proxy part)"
url="https://snowflake.torproject.org"
license=('BSD')
arch=('x86_64' 'aarch64' 'armv7h')
depends=('glibc')
makedepends=('go')
source=("$pkgname-$pkgver.tar.gz::https://gitlab.torproject.org/tpo/anti-censorship/pluggable-transports/snowflake/-/archive/v$pkgver/snowflake-v$pkgver.tar.gz"
snowflake-proxy.service)
sha256sums=('4272cdea61107792d8a7098063447d65ee3d27f71e9ba222e414bbcfafe11560'
'81ed80bea97fb9874734d4ec7ccb9a850e6aa5b186a354990066344446bd1412')
b2sums=('bacf5398a62c2783b51f5424ea6cb8e2fe07ea93da5651ec0b8a1d6e3d06e079d456188c2a958da99884796da138375b1b71c39091111a9fdad7353e1ec0b98f'
'2ba698a76a06b8ebee3cd8c44562783aa3939f66528d1573ac93a59dcc6a8de61f160b5dbc0e8b83c2473bedf037d69fbee9b33befa24027693e556fd5d3d575')
build() {
cd "snowflake-v$pkgver"
export CGO_CPPFLAGS="$CPPFLAGS"
export CGO_CFLAGS="$CFLAGS"
export CGO_CXXFLAGS="$CXXFLAGS"
export CGO_LDFLAGS="$LDFLAGS"
export GOFLAGS="-buildmode=pie -trimpath -ldflags=-linkmode=external -mod=readonly -modcacherw"
go build -v -o proxy/snowflake-proxy ./proxy
}
package() {
cd "snowflake-v$pkgver"
install -Dm0755 proxy/snowflake-proxy "$pkgdir/usr/bin/snowflake-proxy"
install -Dm0644 "$srcdir/snowflake-proxy.service" "$pkgdir/usr/lib/systemd/system/snowflake-proxy.service"
install -Dm0644 LICENSE "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
}
|