blob: 49299261aadd7ef45ecd41b2392c29f06d71555c (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
|
# Maintainer: Deon Spengler <deon[at]spengler[dot]co[dot]za>
# Contributor: DJ Lucas <dj_AT_linuxfromscratch_DOT_org>
# Contributor: Steven Hiscocks <steven [at] hiscocks [dot] me [dot] uk>
# Contributor: Andre Wayand <aur-sogo@awayand.sleepmail.com>
pkgname=sogo2
pkgdesc="groupware server built around OpenGroupware.org (OGo) and the SOPE application server"
pkgver=2.3.23
pkgrel=1
arch=('i686' 'x86_64')
url="http://www.sogo.nu/"
license=('GPL')
depends=("sope2>=${pkgver}"
'gnustep-base'
'libmemcached'
'memcached')
makedepends=('gcc-objc'
'gnustep-base'
'libwbxml'
'libmemcached')
conflicts=('sogo'
'sogo-openchange'
'sogo2-openchange')
replaces=('sogo-activesync'
'sogo2-activesync')
provides=('sogo-activsync'
'sogo2-activesync')
optdepends=(
'postgresql: run database server for sogo locally'
'mariadb: run database server for sogo locally'
'openldap: run directory server for sogo locally'
'postfix: run smtp server for sogo locally'
'dovecot: run imap server for sogo locally'
'courier-imap: run imap server for sogo locally'
'nginx: webserver to provide web interface locally'
'apache: webserver to provide web interface locally'
'lighttpd: webserver to provide web interface locally'
'funambol: sync mobile devices with sogo contacts, events, tasks via SyncML')
backup=('etc/sogo/sogo.conf'
'etc/httpd/conf/extra/SOGo.conf'
'etc/conf.d/sogo')
install=sogo.install
options=('!strip')
source=(
http://www.sogo.nu/files/downloads/SOGo/Sources/SOGo-${pkgver}.tar.gz
sogo_configure.patch
sogo.service
sogo.confd
)
sha256sums=('2f22fb0d11c62f16cbe40fe2e627a2274981a67691f9502d08b8f70ec00da376'
'e64ea4aa0ddf29785de8d786ab7ab09f940bfe316b6f1deeb8d04d9d16d35db1'
'0720b9ad35a05d86d794c7adbf18277ecde57ed147e96f6105acca93f19d3b8c'
'8ee0d1ad77e998ea801053fce175d8c4a1c55dcc5ee1ff78f0a8e3797187a6a7')
prepare() {
cd "$srcdir/SOGo-${pkgver}"
patch configure ../sogo_configure.patch
}
build() {
cd "$srcdir/SOGo-${pkgver}"
./configure --prefix=$(gnustep-config --variable=GNUSTEP_SYSTEM_ROOT) \
--disable-strip \
--disable-debug
make
}
package() {
cd "${srcdir}/SOGo-${pkgver}"
make install DESTDIR="${pkgdir}"
install -D -m 0644 "${srcdir}"/sogo.service \
"${pkgdir}"/usr/lib/systemd/system/sogo.service
install -D -m 0600 "${srcdir}"/SOGo-${pkgver}/Scripts/sogo.conf \
"${pkgdir}"/etc/sogo/sogo.conf
install -D -m 0644 "${srcdir}"/SOGo-${pkgver}/Apache/SOGo.conf \
"${pkgdir}"/etc/httpd/conf/extra/SOGo.conf
install -D -m 0644 "${srcdir}"/SOGo-${pkgver}/Scripts/logrotate \
"${pkgdir}"/etc/logrotate.d/sogo
install -d -m 0755 "${pkgdir}"/usr/lib/sogo/scripts
install -m 0755 "${srcdir}"/SOGo-${pkgver}/Scripts/sql-update-2.2.17_to_2.3.0{,-mysql}.sh \
"${pkgdir}"/usr/lib/sogo/scripts/
install -D -m 0644 "${srcdir}"/sogo.confd \
"${pkgdir}"/etc/conf.d/sogo
# ActiveSync
cd "${srcdir}/SOGo-${pkgver}/ActiveSync"
make PYTHON=/usr/bin/python2 install DESTDIR="${pkgdir}" \
GNU_SYSTEM_ADMIN_TOOLS="/usr/bin"
}
|