blob: 26034d976e7aa1acc6d76466a83f37650168e761 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
|
# Maintainer: Rafael Fontenelle <rafaelff@gnome.org>
pkgname=solanum
pkgver=3.0.1.r0.g3f84b1d
pkgrel=2
pkgdesc="A pomodoro timer for the GNOME desktop"
arch=(x86_64)
url="https://gitlab.gnome.org/World/solanum"
license=('GPL3')
depends=('libadwaita' 'gst-plugins-bad-libs')
makedepends=('rust' 'meson' 'git')
checkdepends=('appstream-glib')
_commit=3f84b1d0c46fe1a3daef2940b1d0747222023984 # tags/v3.0.1
source=("git+$url#commit=$_commit"
meson-drop-unused-argument.patch)
sha256sums=('SKIP'
'e2d30fb22bb8948659d909064df462bd74f44f2eb768757d041618aecb36b245')
prepare() {
cd $pkgname
git apply "$srcdir/meson-drop-unused-argument.patch"
}
pkgver() {
cd $pkgname
git describe --long --tags | sed 's/\([^-]*-g\)/r\1/;s/^v//;s/-/./g'
}
build() {
arch-meson $pkgname build
meson compile -C build
}
check() {
meson test -C build
}
package() {
meson install -C build --destdir="$pkgdir"
}
|