PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41

# Maintainer: HatsuSixty <hatsunotsus+aur(at)gmail(dot)com>

# If you just use "hatsunotsus(at)gmail(dot)com"
# instead of "hatsunotsus+aur(at)gmail(dot)com"
# I probably won't read your email

pkgname=solar2d
pkgver=2023.3697
pkgrel=1
pkgdesc="Simple to learn and use, completely free and open source 2D game engine"
arch=('x86_64')
url='https://solar2d.com/'
provides=('Solar2D' 'Solar2DBuilder' 'Solar2DSimulator')
license=('MIT')
depends=('glu' 'zlib' 'openal' 'freetype2' 'libpng' 'libjpeg' 'openssl-1.1' 'curl' 'sdl2' 'java-runtime')
makedepends=('squashfs-tools')
source=("https://github.com/coronalabs/corona/releases/download/3697/Solar2D-Linux-${pkgver}_amd64.snap")
sha256sums=('509a1aaf622bf41490dcfe63aa040ba4f327e9e1a4c2a7b5aa32c749a059f31a')

prepare() {
    echo "Extracting snap file..."
    unsquashfs -q -f -d "${srcdir}/${pkgname}" "Solar2D-Linux-${pkgver}_amd64.snap"
}

package() {
    # Install files
    install -d "${pkgdir}/opt/Solar2D"
    cp -r "${srcdir}/${pkgname}/usr/local/bin/Solar2D/." "${pkgdir}/opt/Solar2D"

    # Desktop Entry
    sed -i 's|${SNAP}/meta/gui/solar2d.png|solar2d|g' "${srcdir}/${pkgname}/meta/gui/solar2d.desktop"
    sed -i 's|Exec=solar2d|Exec=Solar2D|g' "${srcdir}/${pkgname}/meta/gui/solar2d.desktop"
    install -Dm644 "${srcdir}/${pkgname}/meta/gui/solar2d.desktop" -t "${pkgdir}/usr/share/applications"
    install -Dm644 "${srcdir}/${pkgname}/meta/gui/solar2d.png" "${pkgdir}/usr/share/pixmaps/solar2d.png"

    # Symlink binaries to /usr/bin
    install -d "${pkgdir}/usr/bin"
    ln -s "/opt/Solar2D/Solar2D" "${pkgdir}/usr/bin"
    ln -s "/opt/Solar2D/Solar2DBuilder" "${pkgdir}/usr/bin"
    ln -s "/opt/Solar2D/Solar2DSimulator" "${pkgdir}/usr/bin"
}