PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51

# Maintainer: Franck STAUFFER <franck.stauffer@monaco.mc>
# Contributor: carstene1ns <arch carsten-teibes de> - http://git.io/ctPKG
# Contributor: Fernando Carmona Varo <ferkiwi @t gmail dot com>
# Contributor: BenObiWan <benobiwan @t gmail dot com>

pkgname=solarus-git
pkgver=1.5.3.r1139.gf0eadc40f
pkgrel=2
pkgdesc="An open-source adventure 2D game engine (git version)"
arch=('i686' 'x86_64')
url="http://www.solarus-games.org/"
license=('GPL3')
depends=('glm'
         'hicolor-icon-theme'
         'libmodplug>=0.8.8.4'
         'libvorbis'
         'luajit>=2.0'
         'openal'
         'physfs'
         'qt5-base'
         'qt5-tools'
         'sdl2>=2.0.6'
         'sdl2_image'
         'sdl2_ttf')
makedepends=('git' 'cmake')
provides=('solarus')
conflicts=('solarus')
source=($pkgname::'git+https://gitlab.com/solarus-games/solarus.git')
md5sums=('SKIP')

pkgver() {
  cd "$pkgname"
  git describe --long --tag | sed 's/v//;s/\([^-]*-g\)/r\1/;s/-/./g'
}

prepare() {
  cd $pkgname
  cmake -Wno-dev -DCMAKE_INSTALL_PREFIX="/usr" -DCMAKE_C_FLAGS="$CFLAGS" -DCMAKE_CXX_FLAGS="$CXXFLAGS $CPPFLAGS" -DCMAKE_EXE_LINKER_FLAGS="$LDFLAGS" .
}

build() {
  make -C "$pkgname"
}

check() {
  make -C "$pkgname" test
}

package() {
  make -C "$pkgname" DESTDIR="$pkgdir/" install
}