blob: d7a115aea587e5dfe09793cbc5da8a39f9082dd5 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
|
# Maintainer: txtsd <aur.archlinux@ihavea.quest>
# Maintainer: Donald Webster <fryfrog@gmail.com>
# Contributor: Daniel Egeberg <daniel.egeberg@gmail.com>
# Contributor: Justin Dray <justin@dray.be>
# Helpful URL: https://services.sonarr.tv/v1/releases
pkgname=sonarr
_pkgname=Sonarr
pkgver=4.0.10.2544
pkgrel=10
pkgdesc='Smart PVR for newsgroup and torrent users'
arch=(x86_64 aarch64 armv7h)
url='https://sonarr.tv'
license=('GPL-3.0-or-later')
groups=(servarr)
depends=(
aspnet-runtime-6.0
gcc-libs
glibc
sqlite
ffmpeg
)
makedepends=(dotnet-sdk-6.0 yarn)
optdepends=(
'postgresql: postgresql database'
'sabnzbd: usenet downloader'
'nzbget: usenet downloader'
'qbittorrent: torrent downloader'
'deluge: torrent downloader'
'rtorrent: torrent downloader'
'nodejs-flood: torrent downloader'
'vuze: torrent downloader'
'aria2: torrent downloader'
'transmission-cli: torrent downloader (CLI and daemon)'
'transmission-gtk: torrent downloader (GTK+)'
'transmission-qt: torrent downloader (Qt)'
'jackett: torrent indexer proxy'
'nzbhydra2: torznab and usenet indexer proxy'
'prowlarr: torrent and usenet indexer proxy'
'autobrr: irc, torrent and usenet indexer proxy'
)
install=sonarr.install
source=(
"${pkgname}-${pkgver}.tar.gz::https://github.com/Sonarr/Sonarr/archive/refs/tags/v${pkgver}.tar.gz"
package_info
sonarr.service
sonarr.sysusers
sonarr.tmpfiles
sonarr.install
)
sha256sums=('d6f1b1d04ea572cfd2aba72d8adac1925f544c43b99f31f3a047588f8369be78'
'19112dc0051224b4de66f28077c93b6ee06e163b5194e6aecf62dedf66ff45a9'
'b2673e7b2c7964ceb9672a078797d12fb3c1c8ea908bfaf6330514b8644b0ba2'
'00141d4cbf34daa6d91b26179d4847ec970e2767382e18fdf9af2ec84a0ff43e'
'0acb3697a5001b00f79269581cd08645f9d5e1e9f0a57cc3e7deeb12d66accc9'
'3d912d367eeb89ead06dc9dc45de093f48ddc601188731d54775c33e04e369aa')
case ${CARCH} in
x86_64) _CARCH='x64' ;;
aarch64) _CARCH='arm64' ;;
armv7h) _CARCH='arm' ;;
esac
_framework='net6.0'
_runtime="linux-${_CARCH}"
_output='_output'
_artifacts="${_output}/${_framework}/${_runtime}/publish"
_branch='main'
prepare() {
cd "${_pkgname}-${pkgver}"
# Fix CVE-2024-43485
sed 's/System\.Text\.Json" Version="6\.0\.9"/System\.Text\.Json" Version="6\.0\.10"/' -i src/NzbDrone.Common/Sonarr.Common.csproj
sed 's/System\.Text\.Json" Version="6\.0\.9"/System\.Text\.Json" Version="6\.0\.10"/' -i src/NzbDrone.Core/Sonarr.Core.csproj
# Remove upstream dotnet version
rm global.json
# Prepare backend
export DOTNET_CLI_TELEMETRY_OPTOUT=1
export DOTNET_NOLOGO=1
export DOTNET_SKIP_FIRST_TIME_EXPERIENCE=1
dotnet restore "src/${_pkgname}.sln" \
--runtime "${_runtime}" \
--locked-mode
# Prepare frontend
yarn install --frozen-lockfile --network-timeout 120000
}
build() {
cd "${_pkgname}-${pkgver}"
# Build backend
export DOTNET_CLI_TELEMETRY_OPTOUT=1
export DOTNET_NOLOGO=1
export DOTNET_SKIP_FIRST_TIME_EXPERIENCE=1
dotnet build "src/${_pkgname}.sln" \
--framework "${_framework}" \
--runtime "${_runtime}" \
--no-self-contained \
--no-restore \
--configuration Release \
-p:Platform=Posix \
-p:AssemblyVersion=${pkgver} \
-p:AssemblyConfiguration=${_branch} \
-p:RuntimeIdentifiers="${_runtime}" \
-t:PublishAllRids \
&& dotnet build-server shutdown # Build servers do not terminate automatically
# Remove ffprobe, Service Helpers, Update, and Windows files
rm "${_artifacts}/ffprobe"
rm "${_artifacts}/ServiceInstall"*
rm "${_artifacts}/ServiceUninstall"*
rm "${_artifacts}/Sonarr.Windows."*
rm -rf "${_output}/Sonarr.Update"
# Build frontend
yarn run build --env production
}
check() {
cd "${_pkgname}-${pkgver}"
# Skip Tests:
local _filters='Category!=ManualTest'
_filters+='&Category!=AutomationTest'
_filters+='&Category!=IntegrationTest'
_filters+='&Category!=WINDOWS'
# These tests fail because /etc/arch-release doesn't contain a ${VERSION_ID}
# See: https://github.com/Sonarr/Sonarr/issues/7299
_filters+='&FullyQualifiedName!~should_get_version_info'
_filters+='&FullyQualifiedName!~should_get_version_info_from_actual_linux'
# Prepare for tests
mkdir -p ~/.config/Sonarr
# Test backend
export DOTNET_CLI_TELEMETRY_OPTOUT=1
export DOTNET_NOLOGO=1
export DOTNET_SKIP_FIRST_TIME_EXPERIENCE=1
dotnet test src \
--runtime "${_runtime}" \
--configuration Release \
--filter "${_filters}" \
--no-build
}
package() {
cd "${_pkgname}-${pkgver}"
install -dm755 "${pkgdir}/usr/lib/sonarr/bin/UI"
# Copy backend
cp -dpr --no-preserve=ownership "${_artifacts}/"* "${pkgdir}/usr/lib/sonarr/bin"
# Copy frontend
cp -dpr --no-preserve=ownership "${_output}/UI/"* "${pkgdir}/usr/lib/sonarr/bin/UI"
# Use system ffprobe
ln -s /usr/bin/ffprobe "${pkgdir}/usr/lib/sonarr/bin/ffprobe"
# License
install -Dm644 LICENSE.md "${pkgdir}/usr/share/licenses/${pkgname}"
cd "${srcdir}"
# Disable built in updater.
install -Dm644 package_info "${pkgdir}/usr/lib/sonarr"
echo "PackageVersion=${pkgver}-${pkgrel}" >> "${pkgdir}/usr/lib/sonarr/package_info"
# Systemd
install -Dm644 sonarr.service "${pkgdir}/usr/lib/systemd/system/sonarr.service"
install -Dm644 sonarr.sysusers "${pkgdir}/usr/lib/sysusers.d/sonarr.conf"
install -Dm644 sonarr.tmpfiles "${pkgdir}/usr/lib/tmpfiles.d/sonarr.conf"
}
|