blob: 9cf54ab21cdbe64b4a56cc242783de17cc95e518 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
|
# Maintainer: callmetango
# Contributor: Felix Yan <felixonmars@archlinux.org>
# Contributor: Antonio Rojas <arojas@archlinux.org>
# Contributor: Andrea Scarpino <andrea@archlinux.org>
pkgname=sonic-sysguard-library
pkgver=6.7.2
pkgrel=1
pkgdesc='Library to retrieve information on the current status of computer hardware'
arch=(x86_64)
url='https://github.com/Sonic-DE/sonic-sysguard-library'
license=(LGPL-2.0-or-later)
depends=(gcc-libs
glibc
kconfig
kdeclarative
ki18n
kitemmodels
knewstuff
kpackage
kquickcharts
kservice
libdrm
libnl
libpcap
lm_sensors
qt6-5compat
qt6-base
qt6-declarative
solid
sonic-frameworks-auth
sonic-frameworks-core-addons
sonic-frameworks-quick-ui)
makedepends=(qt6-tools
sonic-frameworks-cmake-modules)
provides=(libksysguard)
conflicts=(libksysguard)
groups=(sonicde)
source=("$pkgname-$pkgver.tar.gz::${url}/archive/refs/tags/${pkgver}.tar.gz")
sha256sums=('bc6602dc09c7b19b0ade4883173f7d243375667f2be825e6b7363b17f2ccd643')
build() {
cmake -B build -S $pkgname-$pkgver \
-DCMAKE_INSTALL_LIBEXECDIR=lib \
-DBUILD_TESTING=OFF
cmake --build build
}
package() {
DESTDIR="$pkgdir" cmake --install build
setcap CAP_NET_RAW=+ep "$pkgdir"/usr/lib/ksysguard/ksgrd_network_helper
}
|