blob: f14229bc0189e22fb7db5ec623c9138d501c6378 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
|
# Maintainer: Pavel Olizko <contact@nolight.dev>
# Contributor: Massimiliano Torromeo <mtorromeo@archlinux.org>
pkgname=sonora
pkgver=0.42.2
pkgrel=1
pkgdesc='A native music streaming client, built with Rust and GPUI'
arch=('x86_64' 'aarch64')
url='https://github.com/sonorahq/sonora'
license=('GPL-3.0-or-later')
depends=('glibc' 'alsa-lib' 'dbus' 'fontconfig' 'hicolor-icon-theme' 'libxcb'
'libxkbcommon' 'libxkbcommon-x11' 'sqlite' 'vulkan-icd-loader' 'wayland')
optdepends=('vulkan-radeon: Vulkan driver for AMD GPUs'
'vulkan-intel: Vulkan driver for Intel GPUs'
'nvidia-utils: Vulkan driver for NVIDIA GPUs'
'pipewire-alsa: audio output through PipeWire'
'pulseaudio-alsa: audio output through PulseAudio'
'webkit2gtk-4.1: sign in to YouTube Music through a browser window')
makedepends=('rust' 'cmake')
options=('!lto')
source=("https://github.com/sonorahq/sonora/archive/refs/tags/v${pkgver}/${pkgname}-${pkgver}.tar.gz")
sha256sums=('4b78056eee06031d82902725d60cf3ebb76141576483fad1884170db316af1bc')
prepare() {
cd "${pkgname}-${pkgver}"
cargo fetch
}
build() {
cd "${pkgname}-${pkgver}"
RUSTFLAGS='-C link-args=-Wl,-z,shstk' cargo build --frozen --release
}
package() {
cd "${pkgname}-${pkgver}"
install -Dm0755 target/release/sonora "${pkgdir}/usr/bin/sonora"
install -Dm644 assets/linux/sonora.desktop \
"${pkgdir}/usr/share/applications/sonora.desktop"
install -Dm644 assets/linux/sonora.svg \
"${pkgdir}/usr/share/icons/hicolor/scalable/apps/sonora.svg"
for icon in assets/linux/icons/hicolor/*/apps/sonora.png; do
local size
size=$(basename "$(dirname "$(dirname "${icon}")")")
install -Dm644 "${icon}" \
"${pkgdir}/usr/share/icons/hicolor/${size}/apps/sonora.png"
done
install -Dm644 COPYING "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
install -Dm644 THIRD-PARTY.md "${pkgdir}/usr/share/licenses/${pkgname}/THIRD-PARTY.md"
install -Dm644 assets/fonts/LICENSE.txt \
"${pkgdir}/usr/share/licenses/${pkgname}/LICENSE.Inter"
install -Dm644 assets/icons/LICENSE \
"${pkgdir}/usr/share/licenses/${pkgname}/icons/LICENSE"
for licence in assets/icons/*/LICENSE; do
local pack
pack=$(basename "$(dirname "${licence}")")
install -Dm644 "${licence}" \
"${pkgdir}/usr/share/licenses/${pkgname}/icons/LICENSE.${pack}"
done
}
|