blob: 13c3df74f09c6d2a1e1585f17e5810f2fdb4c3ca (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
|
# Maintainer: Gordian Edenhofer <gordian.edenhofer@gmail.com>
# Submitter: Schala Zeal <schalaalexiazeal@gmail.com>
pkgname=spigot
_pkgver=1.17.1
_build=131
pkgver="${_pkgver}+b${_build}"
pkgrel=3
pkgdesc="High performance Minecraft server implementation"
arch=('any')
url="https://www.spigotmc.org/"
license=("LGPL")
depends=("java-runtime-headless>=16" 'tmux' 'sudo' 'fontconfig' 'bash' 'awk' 'sed')
optdepends=("tar: needed in order to create world backups"
"netcat: required in order to suspend an idle server")
makedepends=("java-environment>=16" 'git')
provides=("minecraft-server=${_pkgver%_*}" "bukkit=${_pkgver%_*}" "craftbukkit=${_pkgver%_*}")
conflicts=("bukkit" "craftbukkit" "spigot-patcher")
backup=("etc/conf.d/${pkgname}")
install="${pkgname}.install"
source=("BuildTools-${_pkgver}+b${_build}.jar::https://hub.spigotmc.org/jenkins/job/BuildTools/${_build}/artifact/target/BuildTools.jar"
"${pkgname}-backup.service"
"${pkgname}-backup.timer"
"${pkgname}.service"
"${pkgname}.sysusers"
"${pkgname}.tmpfiles"
"${pkgname}.conf"
"${pkgname}.sh")
sha512sums=('eb2aad8f40fdcbbd34e1bedf2c81f11141f3f25f39571e8d7e7894a204b09b6d4d454c9f44e31ddb60c731247b8e0caf9b7373e1e87f83e4bd8bda8e58619dd4'
'03ba1032b687553831021cfb0bed489e6301d0446c3b4f56d989d203855952911f3b1caaa00596f4731060ddf6684f66c3d674f3c5546b600cbe6585fc8560fb'
'76c77e47c442b477216e968db2213612579b24add54cf0e0512f808498673500b4d24e59bce70b1e7479d724a9a897ceb154e937b88a476beb11c8776258b36c'
'5a32439ff4b8fa9db89e9242206cf99109e0b00f29f87711c25342dda522171d999f7e18fb2013437ddf62cfec05b6677601933233aaf42bcb5d67eb7a1469ee'
'eac1deb53fa9d522af272fa2d9093b98e7d51aa4c0730471e5c575752733500b84a06bc19d1fe83b4c48e41b7f0e11efb23881bfadce4a40d2bfed7cbe5a5bf7'
'f3b3005a8ee643cb7d8fa24a3d1141604157efd2147d07aa7f839b070370cbed66ccf3c34317181e9601f2aadb5224002617226c99e36b677c0fc3de0b42d0d8'
'2f5d71911c9ee7e7763d3300f335245a531a9e00d23e4d007ce76f4175dd7ecd9d8f0425af86a885797764690db64bfa558b49719f3d9d85a46df89443bcdf7b'
'a83df4c9f8b0908be692e72460d85c40ac7c341d5015f25978e81fb1eb22aec4c61974dacbb07425dbcebe763ad452c25017c949bc89748cd88a05a52ed85f38')
_game="spigot"
_server_root="/srv/craftbukkit"
build() {
export MAVEN_OPTS="-Xmx2g"
java -jar "BuildTools-${_pkgver}+b${_build}.jar" --rev "${_pkgver}"
}
package() {
install -Dm644 "${_game}.conf" "${pkgdir}/etc/conf.d/${_game}"
install -Dm755 "${_game}.sh" "${pkgdir}/usr/bin/${_game}"
install -Dm644 "${_game}.service" "${pkgdir}/usr/lib/systemd/system/${_game}.service"
install -Dm644 "${_game}-backup.service" "${pkgdir}/usr/lib/systemd/system/${_game}-backup.service"
install -Dm644 "${_game}-backup.timer" "${pkgdir}/usr/lib/systemd/system/${_game}-backup.timer"
install -Dm644 "${_game}-${_pkgver}.jar" "${pkgdir}${_server_root}/${_game}.${_pkgver}.jar"
install -Dm644 "${_game}.sysusers" "${pkgdir}/usr/lib/sysusers.d/${_game}.conf"
install -Dm644 "${_game}.tmpfiles" "${pkgdir}/usr/lib/tmpfiles.d/${_game}.conf"
ln -s "${_game}.${_pkgver}.jar" "${pkgdir}${_server_root}/${_game}.jar"
# Link the log files
mkdir -p "${pkgdir}/var/log/"
install -dm775 "${pkgdir}/${_server_root}/logs"
ln -s "${_server_root}/logs" "${pkgdir}/var/log/${_game}"
# Give the group write permissions and set user or group ID on execution
chmod g+ws "${pkgdir}${_server_root}"
# Make plugins folder ready for drag and drop
install -dm777 "${pkgdir}/${_server_root}/plugins"
}
|