blob: 0e6dae9b07fab9139aac99cc2d281becc72cf79c (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
|
# Maintainer: Damjan Georgievski <gdamjan@gmail.com>
pkgname=spinframework-cli
_realname=spin
pkgver=4.2.2 # renovate: datasource=github-tags depName=spinframework/spin
pkgrel=1
pkgdesc='an open source framework for building and running fast, secure, and composable cloud microservices with WebAssembly'
arch=('x86_64')
url="https://spinframework.dev/"
license=('Apache-2.0')
depends=('glibc' 'libgcc' 'libstdc++' 'openssl' 'sqlite')
makedepends=('cargo' 'rust-wasm' 'cmake' 'git')
source=("https://github.com/spinframework/spin/archive/v${pkgver}/${_realname}-${pkgver}.tar.gz")
options=("!lto" "!debug")
# this package was previously called fermyon-spin
conflicts=("fermyon-spin")
provides=("fermyon-spin")
prepare() {
cd $_realname-$pkgver
cargo fetch --locked --target "$CARCH-unknown-linux-gnu"
}
build() {
cd $_realname-$pkgver
export RUSTUP_TOOLCHAIN=stable
export CARGO_TARGET_DIR=target
export LIBSQLITE3_SYS_USE_PKG_CONFIG=1 # force building against system sqlite libraries (negate bundled feature)
cargo build --frozen --target "$CARCH-unknown-linux-gnu" --release --bin spin
}
package() {
install -Dm0755 $_realname-$pkgver/target/$CARCH-unknown-linux-gnu/release/spin "$pkgdir"/usr/bin/spin-cli
}
sha256sums=('94cb46d5b41bf4e80e2a8deee394a17379881c1e0f468eef411954a922409d7e')
|