blob: 33d118d5770e15e4475891eefa30004a65af2fb2 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
|
#
# Maintainer: Iacopo Isimbaldi <isiachi@rhye.it>
#
pkgbase="spl-dkms-git"
pkgname=("spl-dkms-git" "spl-utils-dkms-git")
pkgver=0.7.0_rc1_r3_gcb81c0c
pkgrel=1
license=('GPL')
makedepends=("git")
arch=("i686" "x86_64")
url="http://zfsonlinux.org/"
source=("git+https://github.com/zfsonlinux/spl.git"
"spl-utils.hostid")
sha256sums=('SKIP'
'ad95131bc0b799c0b1af477fb14fcf26a6a9f76079e48bf090acb7e8367bfd0e')
pkgver() {
cd "${srcdir}/spl"
git describe --match "spl-*" --long --tags | sed -e 's|spl-||' -e 's|-\([0-9]*-g\)|-r\1|' -e 's|[-: ]|_|g'
}
build() {
cd "${srcdir}/spl"
./autogen.sh
_at_enable=""
[ "${CARCH}" == "i686" ] && _at_enable="--enable-atomic-spinlocks"
./configure --prefix=/usr \
--libdir=/usr/lib \
--sbindir=/usr/bin \
--with-config=user \
${_at_enable}
make
}
package_spl-dkms-git() {
pkgdesc="Solaris Porting Layer kernel modules."
depends=("dkms" "spl-utils-dkms-git=${pkgver}-${pkgrel}")
provides=("spl")
conflicts=("spl-git" "spl-lts" "spl-dkms")
install=spl.install
dkmsdir="${pkgdir}/usr/src/spl-${pkgver%%_*}"
install -d "${dkmsdir}"
cp -a ${srcdir}/spl/. ${dkmsdir}
cd "${dkmsdir}"
make clean distclean
find . -name ".git*" -print0 | xargs -0 rm -fr --
scripts/dkms.mkconf -v ${pkgver%%_*} -f dkms.conf -n spl
chmod g-w,o-w -R .
}
package_spl-utils-dkms-git() {
pkgdesc="Solaris Porting Layer kernel module support files."
provides=("spl-utils")
conflicts=("spl-utils-git" "spl-utils-lts" "spl-utils")
cd "${srcdir}/spl"
make DESTDIR="${pkgdir}" install
install -D -m644 "${srcdir}"/spl-utils.hostid "${pkgdir}"/etc/hostid
}
|