blob: 9e717133593b1ce4acf1662aa29ab5eb72288578 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
|
# Maintainer: Butui Hu <hot123tea123@gmail.com>
pkgname=sqlacodegen
_name=sqlacodegen
pkgver=2.3.0
pkgrel=1
pkgdesc='Automatic model code generator for SQLAlchemy'
arch=(any)
url='https://github.com/agronholm/sqlacodegen'
license=(MIT)
depends=(
python-inflect
python-sqlalchemy
)
makedepends=(
python-setuptools
python-pip
)
checkdepends=(
python-mysql-connector
python-psycopg2
python-pytest
python-pytest-cov
)
source=("${pkgname}-${pkgver}.tar.gz::https://files.pythonhosted.org/packages/source/${_name::1}/${_name}/${_name}-${pkgver}.tar.gz")
sha512sums=('80e3d61c6b56bfe3ecace52d6c5aeecef9ebdd2256b67f437a1a0c29e48bd7a83a27cccaddc1dd1200653f21f3ebd165ad37da93af264a13ed196b88febf3ac5')
build() {
cd "${_name}-${pkgver}"
python setup.py build
}
check() {
cd "${_name}-${pkgver}"
PYTHONPATH="${PWD}/build/lib" pytest -v .
}
package() {
cd "${_name}-${pkgver}"
python setup.py install --root="${pkgdir}" --optimize=1 --skip-build
install -Dm644 LICENSE -t "${pkgdir}/usr/share/licenses/${pkgname}"
}
# vim:set ts=2 sw=2 et:
|