blob: 96a0458b6aed0056da5ccac7e71c2effa1c04768 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
|
# Maintainer: Vitalij Berdinskih <vitalij_r2 at outlook dot com>
# Contributor: Håvard Pettersson <mail@haavard.me>
# Contributor: John Trengrove <john@retrofilter.com>
# Contributor: Jakob Gahde <j5lx@fmail.co.uk>
# Contributor: Andrejs Mivreņiks <gim at fastmail dot fm>
# Contributor: Vitaliy Berdinskikh ur6lad[at]i.ua
pkgname=sqlite-jdbc
pkgver=3.43.2.0
pkgrel=1
pkgdesc='JDBC driver for SQLite'
arch=('x86_64')
url='https://github.com/xerial/sqlite-jdbc'
license=('Apache')
depends=('java-runtime>=8')
makedepends=('maven')
source=("https://github.com/xerial/sqlite-jdbc/archive/${pkgver}.tar.gz")
md5sums=('85753c5a34e238e5d1e9a102c9a6e9cd')
sha256sums=('1e2cd64822af1e47c14dfa4d3bc24570d0977fb8bf18a2a30a422ce0428a4686')
prepare() {
# remove unused sqlite binaries
cd ${pkgname}-${pkgver}/src/main/resources/org/sqlite/native
find . ! -path "./Linux/$CARCH/*" -type f -delete
find . -type d -empty -delete
}
build() {
cd ${pkgname}-${pkgver}
mvn package -DskipTests
}
check() {
cd ${pkgname}-${pkgver}
mvn verify
}
package() {
cd ${pkgname}-${pkgver}/target
install -Dm644 "${pkgname}-${pkgver}.jar" "${pkgdir}/usr/share/java/${pkgname}/${pkgname}-${pkgver}.jar"
ln -s "${pkgname}-${pkgver}.jar" "${pkgdir}/usr/share/java/${pkgname}/${pkgname}.jar"
}
# vim:set ts=2 sw=2 et:
|