PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54

# Maintainer: Shengyu Zhang <la@archlinuxcn.org>

pkgname=srain-dev
pkgver=1.0.0rc2.1112.1c367df
_pkgver=1.0.0rc2
pkgrel=1
pkgdesc="Modern IRC client, develop and debug version"
arch=('i686' 'x86_64')
license=('GPL')
url="https://srain.im"
makedepends=('git' 'make' 'gcc' 'pkg-config' 'gettext' 'python-sphinx')
depends=('glib2' 'gtk3' 'libconfig' 'libsoup' 'gdb')
optdepends=(
    'glib-networking: TLS connection support'
    )
conflicts=('srain')
provides=('srain')
source=("git+https://github.com/SrainApp/srain.git#branch=dev/1.0")
sha256sums=('SKIP')
options=('!strip')

_prefix='/usr'

pkgver() {
    cd ${pkgname%-dev}
    echo "${_pkgver}.$(git rev-list --count HEAD).$(git describe --always)"
}

build() {
    cd ${pkgname%-dev}

    ./configure                         \
        --prefix="${_prefix}"           \
        --datadir="${_prefix}/share"    \
        --sysconfdir="/etc"             \
        --enable-debug
    make
    make doc
}

package() {
    cd ${pkgname%-dev}

    make DESTDIR="${pkgdir}" install
    make DESTDIR="${pkgdir}" install-doc
    mv "${pkgdir}${_prefix}/bin/srain"{,-dev}

    cat << EOF > "${pkgdir}${_prefix}/bin/srain"
#!/bin/sh
gdb "${_prefix}/bin/srain-dev" -ex "r \$@" -ex "bt" -ex "q"
EOF

    chmod 755 "${pkgdir}${_prefix}/bin/srain"
}