blob: 529fbd335dfcc340926f311c1df95d80b8e21885 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
|
# Maintainer: Ryan Pepper <pypper@protonmail.com>
# Maintainer: Daniel Landau <daniel@landau.fi>
pkgname=ssb-patchwork
_upstream=patchwork
pkgver=3.11.6
pkgrel=1
pkgdesc="A decentralized messaging and sharing app built on top of Secure Scuttlebutt (SSB)"
arch=('i686' 'x86_64')
url="https://github.com/ssbc/patchwork"
license=('AGPL3')
depends=('libxtst' 'libxext' 'libxkbfile' 'gconf' 'libsodium' 'libxss' 'gtk2' 'alsa-lib' 'nss' 'electron2')
makedepends=('nodejs' 'npm')
options=(!strip)
source=(
"https://github.com/ssbc/${_upstream}/archive/v${pkgver}.tar.gz"
'run.sh'
"${pkgname}.desktop"
)
sha512sums=(
'1e60b23037f12a11d41965ca04f84baa66082fc439f429d4c011c569e0d2d0f524e8c6e7324b8fadbc621b85b85759049f6a6d87b61a89c030ac5fcda7e7cee4'
'582a74d9581c382745b33903f60e40c1fba97a1ff253560fd609ccd133f6074b7827561b559402274e879296b24aad73e2f3f5b9c7f25142e1885de919a2e8b7'
'09292ec2f7c02d741cbeb046bd99293f4d144314d0233252dd34a619e1aacbbbf28078677c0871d367240e29aa50d9197bbe0a35e5b14f7ff9a6288c386124f6'
)
build() {
cd "${srcdir}/${_upstream}-${pkgver}"
# Remove postinstall script that references `electron`
# (we instead need it to reference `electron2`)
sed -i '/postinstall/d' package.json
# Electron's version.
export npm_config_target=$(electron2 -v)
# The architecture of Electron, can be ia32 or x64.
export npm_config_arch=x64
export npm_config_target_arch=x64
# Download headers for Electron.
export npm_config_disturl=https://atom.io/download/electron
# Tell node-pre-gyp that we are building for Electron.
export npm_config_runtime=electron
# Tell node-pre-gyp to build module from source code.
export npm_config_build_from_source=true
# Install all dependencies, and store cache to ~/.electron-gyp.
HOME=~/.electron-gyp npm install --only=production
}
package() {
cd "${srcdir}/${_upstream}-${pkgver}"
install -d "${pkgdir}/opt/${pkgname}"
cp -a * "${pkgdir}/opt/${pkgname}"
install -D assets/icon.png "${pkgdir}/usr/share/icons/hicolor/512x512/apps/${pkgname}.png"
cd "${srcdir}"
install -D run.sh "${pkgdir}/usr/bin/${pkgname}"
install -D "${pkgname}.desktop" "${pkgdir}/usr/share/applications/${pkgname}.desktop"
}
|