PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51

# Maintainer: Frederik Leonhardt <frederik at leonhardt dot co dot nz>
pkgname='ssh2incus-bin'
pkgver=0.9
pkgrel=1
pkgdesc="SSH server for Incus instances"
arch=(
  'x86_64'
  'aarch64'
)
url='https://ssh2incus.com/'
license=('GPL-3.0-only')
depends=()
optdepends=('incus')

backup=('etc/default/ssh2incus')
install=ssh2incus.install
conflicts=('ssh2incus')

source=(
  "https://raw.githubusercontent.com/mobydeck/ssh2incus/refs/tags/${pkgver}/packaging/ssh2incus.service"
  "https://raw.githubusercontent.com/mobydeck/ssh2incus/refs/tags/${pkgver}/packaging/ssh2incus.env"
  "https://raw.githubusercontent.com/mobydeck/ssh2incus/refs/tags/${pkgver}/packaging/config.yaml"
  "https://raw.githubusercontent.com/mobydeck/ssh2incus/refs/tags/${pkgver}/packaging/create-config.yaml"
)
sha256sums=('73cfa1a56765ec898e5a6803bca33357179b3d447e325baf9c6a0b9621a1c804'
            '714c117e53609ce0047af745f143078fa97c7d262d6511fd659b377b5c226fa9'
            '206688edb2bbc6fdc6236a66c26cf81c7b2595d0732cfcae3d9db096591f8128'
            'dd9289ec3f8721e95fdecaf71a5873664decd8018e616916d8f3abea38e3a9ed')
source_x86_64=(
  "https://github.com/mobydeck/ssh2incus/releases/download/${pkgver}/ssh2incus-${pkgver}-linux-amd64.tar.gz"
)
sha256sums_x86_64=('1a770047cbaff8e96f78fa5e02bfbe47bf363cf296d088861bcfd8311a901fd4')
source_aarch64=(
  "https://github.com/mobydeck/ssh2incus/releases/download/${pkgver}/ssh2incus-${pkgver}-linux-arm64.tar.gz"
)
sha256sums_aarch64=('96b0f6ff547cbb32354616c71e98bc7e3b710623f95ea153212ea49ee55fbe7a')

package() {
  if [[ "$CARCH" == "x86_64" ]]; then
    install -Dm755 "$srcdir/ssh2incus-linux-amd64" "$pkgdir/usr/bin/ssh2incus"
  elif [[ "$CARCH" = "aarch64" ]]; then
    install -Dm755 "$srcdir/ssh2incus-linux-arm64" "$pkgdir/usr/bin/ssh2incus"
  fi

  install -Dm644 "$srcdir/ssh2incus.env" "$pkgdir/etc/default/ssh2incus"
  install -Dm644 "$srcdir/config.yaml" "$pkgdir/etc/ssh2incus/config.yaml"
  install -Dm644 "$srcdir/create-config.yaml" "$pkgdir/etc/ssh2incus/create-config.yaml"
  install -Dm644 "$srcdir/ssh2incus.service" "$pkgdir/usr/lib/systemd/system/ssh2incus.service"
  install -Dm644 "$srcdir/README.md" "$pkgdir/usr/share/doc/ssh2incus/README.md"
  install -Dm644 "$srcdir/LICENSE" "$pkgdir/usr/share/licenses/ssh2incus/LICENSE"
}