blob: c01b0567b3a57a94a2354e4ce9dae9fc12a055c9 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
|
# Maintainer: Levente Polyak <anthraxx[at]archlinux[dot]org>
pkgname=sslsplit-git
pkgver=0.5.0.466.7677fe0
pkgrel=1
pkgdesc="Tool for man-in-the-middle attacks against SSL/TLS encrypted network connections"
url="https://www.roe.ch/SSLsplit"
arch=('i686' 'x86_64')
license=('BSD')
depends=('libevent' 'openssl')
makedepends=('git')
checkdepends=('check')
provides=('sslsplit')
conflicts=('sslsplit')
source=(${pkgname}::git+https://github.com/droe/sslsplit)
sha512sums=('SKIP')
pkgver() {
cd ${pkgname}
printf "%s.%s.%s" "$(git describe --tags --abbrev=0)" \
"$(git rev-list --count HEAD)" "$(git rev-parse --short HEAD)"
}
build() {
cd ${pkgname}
make
}
check() {
cd ${pkgname}
make -j1 test
}
package() {
cd ${pkgname}
make PREFIX="${pkgdir}/usr" install
install -Dm 644 LICENSE.md "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
install -Dm 644 README.md "${pkgdir}/usr/share/doc/${pkgname}/README.md"
install -Dm 644 NEWS.md "${pkgdir}/usr/share/doc/${pkgname}/NEWS.md"
}
# vim: ts=2 sw=2 et:
|