summarylogtreecommitdiffstats
path: root/PKGBUILD
blob: 6e920b26e7ae557c15fa8812bd02e5342e363c53 (plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
# Maintainer: Brian Bidulock <bidulock@openss7.org>
# Contributor: Florian Knodt <adlerweb@adlerweb.info>
# Contributor: Jose Riha <jose 1711 gmail com>

pkgname=ssvnc-nojava
_pkgname=ssvnc
pkgver=1.0.29
pkgrel=10
pkgdesc="SSL/SSH VNC viewer no java"
arch=('i686' 'x86_64')
url="http://www.karlrunge.com/x11vnc/ssvnc.html"
license=('GPL')
groups=('network')
depends=('libjpeg.so>=7' 'libxaw' 'openssl' 'tk' 'tcl')
provides=(${_pkgname})
conflicts=(${_pkgname})
makedepends=('imake')
optdepends=('perl' 'xterm' 'smbclient' 'avahi' 'stunnel')
source=(http://downloads.sf.net/sourceforge/$_pkgname/$_pkgname-$pkgver.src.tar.gz
        openssl1.1.patch
        Makefile.patch)
md5sums=('52201aeb0417c2a0fe83639e52da6ae5'
         '6a119a5748a231f63c96044a2761845f'
         '7d35673003f4f25a046c48f803e76e65')

prepare() {
  cd "$_pkgname-$pkgver"
  patch -p1 < "../openssl1.1.patch"
  patch -p0 < "../Makefile.patch"
}

build() {
  cd "$_pkgname-$pkgver"
  sed -i '/wr_tool/s/\$(PREFIX)\/\$(LIB)\/\([^/]*$\)/\/usr\/lib\/ssvnc\/\1/' Makefile
  make JSRC= config
  sed -i 's/ar clq/ar cq/' vnc_unixsrc/libvncauth/Makefile
  make JSRC= all
}

package() {
  cd "$srcdir/$_pkgname-$pkgver"
  make JSRC= PREFIX="$pkgdir/usr" MANDIR="share/man" install
}

# vim:set ts=2 sw=2 et: