PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37

# Maintainer: VerruckteFuchs <derverrucktefuchs@gmail.com>
pkgname=st-zenburn-26px-git
pkgver=r18.ca2114b
pkgrel=1
pkgdesc="Simple terminal with Xresources, scrollback, alpha support, 26px Office Code Pro font, and zenburn colorscheme"
arch=('i686' 'x86_64')
url="https://github.com/DerVerruckteFuchs/st-zenburn"
license=('MIT')
depends=('libxft' 'libxext')
makedepends=('ncurses')
provides=('st-zenburn-26px-git')
conflicts=('st' 'st-xresources-git' 'st-bloated-git' 'st-neonwave-git' 'st-zenburn-git')
source=('git://github.com/DerVerruckteFuchs/st-zenburn')
md5sums=('SKIP')

pkgver() {
  cd st-zenburn
  printf 'r%s.%s' "$(git rev-list --count HEAD)" "$(git rev-parse --short HEAD)"
}

prepare() {
  cd st-zenburn
  sed -i '/\@tic /d' Makefile
  patch -p0 < ./26px-font.patch
}

build() {
  cd st-zenburn
  make X11INC=/usr/include/X11 X11LIB=/usr/lib/X11
}

package() {
  cd st-zenburn
  make PREFIX=/usr DESTDIR="${pkgdir}" TERMINFO="${pkgdir}/usr/share/terminfo" install
  install -Dm644 LICENSE "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
  install -Dm644 README "${pkgdir}/usr/share/doc/${pkgname}/README"
}