PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80

# Maintainer: shulhan <ms@kilabit.info>

pkgname=stackdriver-collectd
pkgver=6.1.4
pkgrel=1

pkgdesc="Stackdriver's monitoring agent based on collectd"
arch=(x86_64)
url='https://github.com/Stackdriver/collectd'
license=('MIT')
groups=()

depends=(
	'curl'
	'iptables'
	'libxml2'
	'lua'
	'systemd-libs'
	'yajl'
)
makedepends=(
	'autoconf'
	'automake'
	'bison'
	'flex'
	'gcc'
	'libtool'
	'pkg-config'
)
optdepends=(
	'mariadb-libs'
)

provides=('stackdriver-collectd')
conflicts=('collectd')

backup=('opt/collectd/etc/collectd.conf')
source=(
	"${pkgname}-v${pkgver}.tar.gz::https://github.com/Stackdriver/collectd/archive/${pkgver}.tar.gz"
	"collectd.conf"
	"stackdriver-collectd.service"
	"stackdriver-collectd.sh"
	"Makefile.am.patch"
)
md5sums=(
	'9e52721f665f636765a6f4dee00109b5'
	'7a2c4528d4ff161d7ac665daedc5fb3c'
	'8b5e44065504669e4ec0eff9fb1484f4'
	'e4da9e61c35f6d74d3d76a02eb441ff2'
	'79f4913634ec33585b7b741e7f2e7dcf'
)

prepare() {
	cd collectd-${pkgver}
	patch --forward --strip=1 --input="${srcdir}/Makefile.am.patch"
	./build.sh
}

build() {
	cd collectd-${pkgver}
	./configure --prefix=/opt/collectd --exec-prefix=/opt/collectd \
		--disable-sensors
	make
}

package() {
    cd collectd-${pkgver}

    # install binaries and libraries
    make DESTDIR="${pkgdir}/" install

    # install license file and documentation
    cd "${srcdir}/collectd-${pkgver}"
    install -Dm 644 COPYING -t "${pkgdir}/usr/share/licenses/${pkgname}/"

    cd ${srcdir}
    install -Dm 644 collectd.conf -t "${pkgdir}/opt/collectd/etc/"
    install -Dm 644 stackdriver-collectd.service -t "${pkgdir}/usr/lib/systemd/system/"
    install -Dm 644 stackdriver-collectd.sh -t "${pkgdir}/etc/profile.d/"
}