blob: 39f1c3318ae6780d65eddc4d1129c657f5b55e36 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
|
# Maintainer: Nikolay Korotkiy <sikmir@gmail.com>
_orgname=huzheng001
_pkgname=stardict-3
_basever=3.0.6
pkgname=stardict-tools-git
pkgver=3.0.6.r657.6a5b1d4
pkgrel=1
pkgdesc='Stardict tools'
arch=('i686' 'x86_64')
url='http://stardict.org/'
license=('GPLv3')
depends=('gtk3' 'glib2' 'libmariadbclient')
makedepends=('git' 'intltool')
provides=("${pkgname//-git}=${pkgver}")
conflicts=(${pkgname//-git})
source=("${_pkgname}::git://github.com/${_orgname}/${_pkgname}.git")
sha256sums=('SKIP')
pkgver() {
cd "${_pkgname}"
REVISION="$(git rev-list --count HEAD).$(git rev-parse --short HEAD)"
printf "%s.r%s" "${_basever}" "${REVISION}"
}
build() {
cd ${srcdir}/${_pkgname}
./autogen.sh
./configure --prefix=/usr --disable-dict
sed -i 's/noinst_PROGRAMS =/bin_PROGRAMS =/' tools/src/Makefile
make
}
package() {
cd ${srcdir}/${_pkgname}
make DESTDIR=$pkgdir/ install
find $pkgdir/usr/bin/ -not -name 'stardict-*' -type f | sed 'p;s#usr/bin/#usr/bin/stardict-#' | xargs -n2 mv
}
|