PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47

# Maintainer: taotieren <admin@taotieren.com>

pkgname=stdexec-git
pkgver=gtc.2026.r5.gb6f8a0e
pkgrel=1
pkgdesc="Senders - A Standard Model for Asynchronous Execution in C++"
url="https://github.com/NVIDIA/stdexec"
arch=(any)
provides=(${pkgname%-git})
conflicts=(${pkgname%-git})
license=('Apache-2.0')
depends=()
makedepends=(
    cmake
    git
    ninja
    meson
    pkgconf
)
source=("${pkgname}::git+${url}.git")
sha256sums=('SKIP')

prepare() {
    git -C "${srcdir}/${pkgname}" clean -dfx
}

pkgver() {
    cd "${srcdir}/${pkgname}"
    (
        set -o pipefail
        git describe --long --tag --abbrev=7 2>/dev/null | sed 's/\([^-]*-g\)/r\1/;s/-/./g' ||
            printf "r%s.%s" "$(git rev-list --count HEAD)" "$(git rev-parse --short=7 HEAD)"
    )
}

build() {
    arch-meson ${pkgname} build
    ninja -C build
}

check() {
    meson test -C ${srcdir}/build
}

package() {
    DESTDIR="${pkgdir}" ninja -C ${srcdir}/build install
}