blob: cbbc4eed30bfb164445cdc1d5c354e827f45f34e (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
|
# Maintainer: SwitchBros <switchbros@proton.me>
pkgname=steam-library-manager
_app_id=io.github.switch_bros.SteamLibraryManager
pkgver=1.5.1
pkgrel=1
pkgdesc="A powerful Steam library organizer for Linux - the modern Depressurizer alternative"
arch=('any')
url="https://github.com/Switch-Bros/SteamLibraryManager"
license=('MIT')
depends=(
'hicolor-icon-theme'
'python>=3.10'
'python-pyqt6'
'python-psutil'
'python-pillow'
'python-vdf'
'python-yaml'
'python-beautifulsoup4'
'python-lxml'
'python-requests'
'python-requests-oauthlib'
'python-qrcode'
'python-steam'
'python-protobuf'
'python-pywebview'
'python-packaging'
'qt6-base'
)
makedepends=(
'python-build'
'python-installer'
'python-setuptools'
'python-wheel'
)
optdepends=(
'python-keyring: secure token storage via system keyring'
'python-steamgriddb: artwork browsing via SteamGridDB'
)
source=("$pkgname-$pkgver.tar.gz::$url/archive/v$pkgver.tar.gz")
sha256sums=('63ceb6f81aa62fe85a06312a7bfb7603e5bbe312807604efa84856eab40bca13')
build() {
cd "SteamLibraryManager-$pkgver"
python -m build --wheel --no-isolation
}
package() {
cd "SteamLibraryManager-$pkgver"
python -m installer --destdir="$pkgdir" dist/*.whl
# Desktop entry
install -Dm644 flatpak/${_app_id}.desktop \
"$pkgdir/usr/share/applications/${_app_id}.desktop"
# Icons (must match Icon= in desktop file)
install -Dm644 steam_library_manager/resources/icon.svg \
"$pkgdir/usr/share/icons/hicolor/scalable/apps/${_app_id}.svg"
install -Dm644 steam_library_manager/resources/icon.png \
"$pkgdir/usr/share/icons/hicolor/512x512/apps/${_app_id}.png"
# Metainfo (for GNOME Software / KDE Discover)
install -Dm644 steam_library_manager/resources/${_app_id}.metainfo.xml \
"$pkgdir/usr/share/metainfo/${_app_id}.metainfo.xml"
# License
install -Dm644 LICENSE \
"$pkgdir/usr/share/licenses/$pkgname/LICENSE"
}
|