PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34

# Maintainer: Jakob Gahde <j5lx@fmail.co.uk>
pkgname=steamkit
pkgver=1.6.3
pkgrel=1
pkgdesc="A .NET library designed to interoperate with Valve's Steam network. It aims to provide a simple, yet extensible, interface to perform various actions on the network."
arch=('any')
url="https://github.com/SteamRE/SteamKit"
license=('LGPL2.1')
depends=('mono' 'protobuf-net')
options=('!strip')
source=("https://github.com/SteamRE/SteamKit/archive/SteamKit_${pkgver}.tar.gz")
md5sums=('b5da732511cbfbbc702a73a8a8dddfb3')

build() {
  cd "${srcdir}/SteamKit-SteamKit_${pkgver}/SteamKit2/SteamKit2"

  xbuild SteamKit2.csproj /p:Configuration=Release
  
  cd "bin/Release"
  monodis SteamKit2.dll --output=SteamKit2.il
  sn -k 1024 SteamKit2.snk
  ilasm /dll /key:SteamKit2.snk SteamKit2.il
}

package() {
  cd "${srcdir}/SteamKit-SteamKit_${pkgver}/SteamKit2/SteamKit2/bin/Release"
  
  install -Dm644 SteamKit2.dll "$pkgdir/usr/lib/SteamKit/SteamKit2.dll"
  install -Dm644 SteamKit2.dll.mdb "$pkgdir/usr/lib/SteamKit/SteamKit2.dll.mdb"
  install -Dm644 changes.txt "$pkgdir/usr/lib/doc/SteamKit/changes.txt"
  
  gacutil -i SteamKit2.dll -root "$pkgdir/usr/lib"
}